带有 DataKinds 的 HList，种类不可推广

Question

我有这段代码 sn-p，它使用了大量的 GHC 扩展：

{-# LANGUAGE ConstraintKinds #-}
{-# LANGUAGE DataKinds #-}
{-# LANGUAGE GADTs #-}
{-# LANGUAGE KindSignatures #-}
{-# LANGUAGE TypeFamilies #-}
{-# LANGUAGE TypeOperators #-}

import GHC.Exts (Constraint)

data HList :: [*] -> * where
    Nil  :: HList '[]
    Cons :: a -> HList l -> HList (a ': l)

type family All (p :: * -> Constraint) (xs :: HList [*]) :: Constraint where
    All p Nil = ()
    All p (Cons x xs) = (p x, All p xs)

GHC 抱怨说：

 ‘HList’ of kind ‘[*] -> *’ is not promotable
    In the kind ‘HList [*]’

为什么我不能将HList 提升为一种类型？我使用 GHC 7.8.2 和 7.11 时遇到同样的错误。

当然，使用内置的'[] 就可以了：

type family All (p :: * -> Constraint) (xs :: [*]) :: Constraint where
    All p '[]       = ()
    All p (x ': xs) = (p x, All p xs)

我想使用我自己的HList 而不是'[]，因为实际的HList 支持追加并且看起来像这样：

type family (:++:) (xs :: [*]) (ys :: [*]) where
    '[] :++:  ys = ys
     xs :++: '[] = xs
    (x ': xs) :++: ys = x ': (xs :++: ys)

data HList :: [*] -> * where
    Nil  :: HList '[]
    Cons :: a -> HList l -> HList (a ': l)
    App  :: Hlist a -> HList b -> HList (a :++: b)

编辑：主要目标是让 GHC 推断

(All p xs, All p ys) ==> All p (xs :++: ys)

这样我可以写

data Dict :: Constraint -> * where
    Dict :: c => Dict c

witness :: Dict (All p xs) -> Dict (All p ys) -> Dict (All p (xs :++: ys))
witness Dict Dict = Dict

我曾希望为附加类型级别列表添加显式表示可以帮助我实现这一目标。是否有另一种方法可以让 GHC 相信上述内容？

Answer 1

我现在看到问题是如何编写(All p xs, All p ys) => All p (xs :++: ys) 的证明。答案当然是归纳法！

我们真正要写的函数的类型是

allAppend :: (p :: Constraint) -> (xs :: [*]) -> (ys :: [*]) 
          -> (All p xs, All p ys) -> All p (xs :++: ys)

但是 Haskell 没有依赖类型。 “伪造”依赖类型通常意味着有一个见证人携带一个类型存在的证据。这让事情变得有些乏味，但目前没有其他办法。我们已经有一个列表的见证人xs - 它正是HList xs。对于约束，我们将使用

data Dict p where Dict :: p => Dict p

那么我们可以把蕴含写成一个简单的函数：

type (==>) a b = Dict a -> Dict b 

所以我们的类型变成了：

allAppend :: Proxy p -> HList xs -> HList ys 
          -> (All p xs, All p ys) ==> (All p (xs :++: ys))

函数的主体非常简单——注意allAppend 中的每个模式如何匹配:++: 定义中的每个模式：

allAppend _ Nil _  Dict = Dict  
allAppend _ _  Nil Dict = Dict 
allAppend p (Cons _ xs) ys@(Cons _ _) Dict = 
  case allAppend p xs ys Dict of Dict -> Dict 

相反的蕴涵All p (xs :++: ys) => (All p xs, All p ys) 也成立。实际上，函数定义是相同的。