如何在 vb HttpWebRequest 上添加过滤器

Question

这段代码运行良好（通过网络请求获取数据）：

 Protected Sub Button3_Click(sender As Object, e As EventArgs) Handles Button3.Click
    Dim oauth_token = "8e269b44b2d7d73eb0b46112af5f4xxx"
    Dim oauth_token_secret = "80da1edadcba1e66e47d2e20f075cxxx"
    Dim oauth_consumer_key = "3626311748bcf2072da2bd475fccfxxx"
    Dim oauth_consumer_secret = "0cbb0df8d840e22b96d4f80449e7exxx"
    Dim oauth_version = "1.0"
    Dim oauth_signature_method = "HMAC-SHA1"
    Dim oauth_nonce = Convert.ToBase64String(New ASCIIEncoding().GetBytes(DateTime.Now.Ticks.ToString()))
    Dim timeSpan = DateTime.UtcNow - New DateTime(1970, 1, 1, 0, 0, 0, 0, DateTimeKind.Utc)
    Dim oauth_timestamp = Convert.ToInt64(timeSpan.TotalSeconds).ToString()
    Dim resource_url = "http://www.inart.com/api/rest/products/store/1"
    Dim baseFormat = "oauth_consumer_key={0}&oauth_nonce={1}&oauth_signature_method={2}" + "&oauth_timestamp={3}&oauth_token={4}&oauth_version={5}"
    Dim baseString = String.Format(baseFormat, oauth_consumer_key, oauth_nonce, oauth_signature_method, oauth_timestamp, oauth_token, oauth_version)
    baseString = String.Concat("GET&", Uri.EscapeDataString(resource_url), "&", Uri.EscapeDataString(baseString))
    Dim compositeKey = String.Concat(Uri.EscapeDataString(oauth_consumer_secret), "&", Uri.EscapeDataString(oauth_token_secret))
    Dim oauth_signature As String
    Using hasher As New HMACSHA1(ASCIIEncoding.ASCII.GetBytes(compositeKey))
        oauth_signature = Convert.ToBase64String(hasher.ComputeHash(ASCIIEncoding.ASCII.GetBytes(baseString)))
    End Using
    Dim headerFormat = "OAuth oauth_nonce=""{0}"", oauth_signature_method=""{1}"", " + "oauth_timestamp=""{2}"", oauth_consumer_key=""{3}"",
                        " + "oauth_token=""{4}"", oauth_signature=""{5}"", " + "oauth_version=""{6}"""
    Dim authHeader = String.Format(headerFormat, Uri.EscapeDataString(oauth_nonce), Uri.EscapeDataString(oauth_signature_method), Uri.EscapeDataString(oauth_timestamp),
                     Uri.EscapeDataString(oauth_consumer_key), Uri.EscapeDataString(oauth_token), Uri.EscapeDataString(oauth_signature), Uri.EscapeDataString(oauth_version))
    ServicePointManager.Expect100Continue = True
    Dim request As HttpWebRequest = DirectCast(WebRequest.Create(resource_url), HttpWebRequest)
    request.Headers.Add("Authorization", authHeader)
    request.Method = "GET"
    request.ContentType = "application/json"
    request.Accept = "application/json"
    Try
        Dim response As WebResponse = request.GetResponse()
        Dim datastream As Stream = response.GetResponseStream
        Dim reader As StreamReader = New StreamReader(datastream)
        Dim responsefromserver As String = reader.ReadToEnd
        If responsefromserver = Nothing Then
            TextBox1.Text = "No response from server"
        Else
            Dim json As String = responsefromserver
            Dim ser As JObject = JObject.Parse(json)
            Dim data As List(Of JToken) = ser.Children().ToList
            Dim output As String = ""
            Dim successReq As Boolean = False
            Dim avDom As String = ""
            Dim counter As Integer = 0
            For Each item As JProperty In data
                item.CreateReader()
                output += "|-" & item.Name.ToString & " :  " & item.Value.ToString & "-"
                output += Environment.NewLine
                counter += 1
            Next
            TextBox1.Text = output
            TextBox1.Text += Environment.NewLine + counter.ToString
            reader.Close()
            response.Close()
        End If
    Catch ex As Exception
        TextBox1.Text = ex.Message.ToString
    End Try
End Sub

当我尝试添加一些过滤器时，它失败了。例如，我尝试以这种方式添加限制过滤器：Dim resource_url = "http://www.inart.com/api/rest/products/store/1?limit=1"。

我确定过滤器没问题，因为我尝试过邮递员应用程序并且它正在工作！ see print screen

我应该更改或添加什么？ 谢谢。

Answer 1

 Dim url As String = "http://www.inart.com/api/rest/products/store/1?limit=1&page=2"
        Dim oauthconsumerkey As String = "3626311748bcf2072da2bd475fccssss"
        Dim oauthconsumersecret As String = "0cbb0df8d840e22b96d4f80449sssss"
        Dim oauthtoken As String = "8e269b44b2d7d73essss2af5f454e"
        Dim oauthtokensecret As String = "80da1edadcba1e66e47d2e2sssss"
        Dim oauthsignaturemethod As String = "HMAC-SHA1"
        Dim oauthversion As String = "1.0"
        Dim oauthnonce As String = Convert.ToBase64String(New ASCIIEncoding().GetBytes(DateTime.Now.Ticks.ToString()))
        Dim timeSpan As TimeSpan = DateTime.UtcNow - New DateTime(1970, 1, 1, 0, 0, 0, 0, DateTimeKind.Utc)
        Dim oauthtimestamp As String = Convert.ToInt64(timeSpan.TotalSeconds).ToString()
        Dim basestringParameters As SortedDictionary(Of String, String) = New SortedDictionary(Of String, String)()
        basestringParameters.Add("limit", "1")
        basestringParameters.Add("page", "2")
        basestringParameters.Add("oauth_version", oauthversion)
        basestringParameters.Add("oauth_consumer_key", oauthconsumerkey)
        basestringParameters.Add("oauth_nonce", oauthnonce)
        basestringParameters.Add("oauth_signature_method", oauthsignaturemethod)
        basestringParameters.Add("oauth_timestamp", oauthtimestamp)
        basestringParameters.Add("oauth_token", oauthtoken)
        Dim baseString As StringBuilder = New StringBuilder()
        baseString.Append("GET" & "&")
        baseString.Append(EncodeCharacters(Uri.EscapeDataString(url.Split("?"c)(0)) & "&"))
        For Each entry As KeyValuePair(Of String, String) In basestringParameters
            baseString.Append(EncodeCharacters(Uri.EscapeDataString(entry.Key & "=" + entry.Value & "&")))
        Next
        Dim finalBaseString As String = baseString.ToString().Substring(0, baseString.Length - 3)
        Dim signingKey As String = EncodeCharacters(Uri.EscapeDataString(oauthconsumersecret)) & "&" + EncodeCharacters(Uri.EscapeDataString(oauthtokensecret))
        Dim hasher As HMACSHA1 = New HMACSHA1(New ASCIIEncoding().GetBytes(signingKey))
        Dim oauthsignature As String = Convert.ToBase64String(hasher.ComputeHash(New ASCIIEncoding().GetBytes(finalBaseString)))
        ServicePointManager.Expect100Continue = False
        Dim wRequest As HttpWebRequest = CType(WebRequest.Create(url), HttpWebRequest)
        Dim authorizationHeaderParams As StringBuilder = New StringBuilder()
        authorizationHeaderParams.Append("OAuth ")
        authorizationHeaderParams.Append("oauth_nonce=" & """" + Uri.EscapeDataString(oauthnonce) & """,")
        authorizationHeaderParams.Append("oauth_signature_method=" & """" + Uri.EscapeDataString(oauthsignaturemethod) & """,")
        authorizationHeaderParams.Append("oauth_timestamp=" & """" + Uri.EscapeDataString(oauthtimestamp) & """,")
        authorizationHeaderParams.Append("oauth_consumer_key=" & """" + Uri.EscapeDataString(oauthconsumerkey) & """,")
        If Not String.IsNullOrEmpty(oauthtoken) Then authorizationHeaderParams.Append("oauth_token=" & """" + Uri.EscapeDataString(oauthtoken) & """,")
        authorizationHeaderParams.Append("oauth_signature=" & """" + Uri.EscapeDataString(oauthsignature) & """,")
        authorizationHeaderParams.Append("oauth_version=" & """" + Uri.EscapeDataString(oauthversion) & """")
        wRequest.Headers.Add("Authorization", authorizationHeaderParams.ToString)
        wRequest.Method = "GET"
        wRequest.ContentType = "application/json"
        wRequest.Accept = "application/json"
        Try
            Dim wResponse As WebResponse = wRequest.GetResponse()
            Dim dataStream As Stream = wResponse.GetResponseStream()
            Dim reader As StreamReader = New StreamReader(dataStream)
            Dim responseFromServer As String = reader.ReadToEnd()
            If responseFromServer = Nothing Then
                TextBox1.Text = "No response from server"
            Else
                Dim json As String = responseFromServer
                Dim ser As JObject = JObject.Parse(json)
                Dim data As List(Of JToken) = ser.Children().ToList
                Dim output As String = ""
                Dim successReq As Boolean = False
                Dim avDom As String = ""
                For Each item As JProperty In data
                    item.CreateReader()
                    output += "|-" & item.Name.ToString & " :  " & item.Value.ToString & "-"
                    output += Environment.NewLine
                Next
                TextBox1.Text = output
            End If
        Catch ex As Exception
            TextBox1.Text = ex.Message.ToString
        End Try

Private Function EncodeCharacters(ByVal data As String) As String
    If data.Contains("!") Then data = data.Replace("!", "%21")
    If data.Contains("'") Then data = data.Replace("'", "%27")
    If data.Contains("(") Then data = data.Replace("(", "%28")
    If data.Contains(")") Then data = data.Replace(")", "%29")
    If data.Contains("*") Then data = data.Replace("*", "%2A")
    If data.Contains(",") Then data = data.Replace(",", "%2C")
    Return data
End Function

这个例子有效