反转列表的方案函数

Question

对于我的编程语言课程，我应该在 Scheme 中编写一个函数来反转列表，而不使用预制的反转函数。到目前为止，我得到的是

(define (reverseList lst)
(COND
((NULL? lst) '())
(ELSE (CONS (reverseList(CDR lst)) (CAR lst)))
))

我遇到的问题是，如果我输入一个列表，比如说(a b c)，它会给我(((() . c) . b) . a)。

我应该如何获得一个没有多组括号和. 的干净列表？

Answer 1

您的实现的问题是 cons 没有接收 list 作为其第二个参数，因此您正在构建的答案不是正确的列表，请记住：正确的列表由consing 一个带有列表的元素构造，最后一个列表为空。

一种可能的解决方法是使用辅助函数在累加器参数中构建答案，consing 反向元素 - 顺便说一下，这个解决方案是尾递归的：

(define (reverse lst)
  (reverse-helper lst '()))

(define (reverse-helper lst acc)
  (if (null? lst)
      acc
      (reverse-helper (cdr lst) (cons (car lst) acc))))

(reverse '(1 2 3 4 5))
=> '(5 4 3 2 1)

Answer 2

你已经成功了一半。结果中元素的顺序是正确的，只有结构需要修复。

你想要的是执行这个转换：

 (((() . c) . b) . a)           ; input
 --------------------
 (((() . c) . b) . a)   ()      ; trans-
  ((() . c) . b)       (a)      ;      for-
   (() . c)          (b a)      ;         mation
    ()             (c b a)      ;               steps
      --------------------
                   (c b a)      ;               result

这很容易编码。中间值的car 和cdr 立即可供我们使用。在每一步，下一个中间结果由(cons (cdr interim-value) interim-result) 构造，interim-result 以一个空列表开始，因为这是我们在这里构造的 - list：

(define (transform-rev input)
   (let step  ( (interim-value    input)       ; initial set-up of 
                (interim-result    '() ) )     ;  the two loop variables
     (if (null? interim-value)
       interim-result                  ; return it in the end, or else
       (step  (car interim-value)      ; go on with the next interim value
              (cons                    ;      and the next interim result
                  (... what goes here? ...)
                  interim-result )))))

interim-result 用作累加器。这就是所谓的“累加器技术”。 step 表示使用“named-let”语法编码的循环步骤。

所以整体反转是

(define (my-reverse lst)
   (transform-rev 
       (reverseList lst)))

您能否调整transform-rev 使其能够接受原始列表作为输入，从而跳过reverseList 调用？您只需要更改数据访问部分，即如何获得下一个中间值，以及添加到中间结果中的内容。

Answer 3

(define (my-reverse L)
 (fold cons '() L)) ;;left fold

Answer 4

遍历列表并继续将列表中的汽车附加到递归调用中。

(define (reverseList lst)
(COND
((NULL? lst) '())
(ELSE (APPEND (reverseList(CDR lst)) (LIST (CAR      lst))))
))

Answer 5

不要使用cons，试试append

(define (reverseList lst)
    (if (null? lst)
        '()
        (append (reverseList (cdr lst)) (list (car lst)) )
    )
)

示例运行将是：

1]=> (reverseList '(a b c 1 2 + -))

>>> (- + 2 1 c b a)

car 只会给你一个符号，但cdr 会给你一个列表

始终确保为append 提供两个列表。

如果您不向cons 提供两个列表，它将为您提供点对(a . b) 而不是列表。

更多信息请参见Pairs and Lists。