Emacs windmove 移动缓冲区而不切换

Question

我的 Emacs Windmove 设置良好且工作正常，但我仍然对它有一点小烦恼。似乎没有办法在不切换两个缓冲区的位置的情况下将一个缓冲区滑到另一个缓冲区上。如何将一个缓冲区滑到另一个缓冲区上，只替换那个缓冲区。

这是我想做的：

   ___________               ___________           ___________
   |    |  B  |             |    |  B  |          |    |  C  |<-----
   | A  |_____|   --->      | A  |_____|   --->   | A  |_____|     |
   |    |  D  |             |    |  C  |          |    |  D  |     |
   |____|_____|             |____|_____|          |____|_____|     |
          Buffer C opens up,  ------^     With a key combo, maybe__|
          covering buffer D               I can slide up buffer C 
                                          to get back buffer D

编辑：我忘了提到我有一些使用 windmove 来实际切换两个缓冲区的 elisp。我想做的用例是有时会在某个窗口中打开一个缓冲区，覆盖我想查看的另一个缓冲区。我想在不干扰其他缓冲区的情况下滑动新打开的缓冲区，并将被覆盖的缓冲区取回。我希望这是有道理的。

Answer 1

(defun slide-buffer (dir)
  "Move current buffer into window at direction DIR.
DIR is handled as by `windmove-other-window-loc'."
  (require 'windmove)
  (let ((buffer (current-buffer))
        (target (windmove-find-other-window dir)))
    (if (null target)
        (user-error "There is no window %s from here" dir)
      (switch-to-prev-buffer)
      (select-window target)
      (switch-to-buffer buffer nil t))))

(defun slide-buffer-up () (interactive) (slide-buffer 'up))
(defun slide-buffer-down () (interactive) (slide-buffer 'down))
(defun slide-buffer-left () (interactive) (slide-buffer 'left))
(defun slide-buffer-right () (interactive) (slide-buffer 'right))

绑定到C-S-<arrow>:

(define-key global-map (kbd "C-S-<up>")    #'slide-buffer-up)
(define-key global-map (kbd "C-S-<down>")  #'slide-buffer-down)
(define-key global-map (kbd "C-S-<left>")  #'slide-buffer-left)
(define-key global-map (kbd "C-S-<right>") #'slide-buffer-right)

Answer 2

在您的评论中，您说您想要一个“组合键来完成它”，意思是 (1) 切换到显示缓冲区 B 的窗口，然后 (2) 切换该窗口中显示的缓冲区以缓冲C。

你现在是怎么做到的？你用钥匙，不是吗？所以你已经有了一个“组合键”。如果你的意思是你想要一个更短的组合键，那么编写一个命令，将绑定到你现在使用的键的命令链接在一起。

#1 有几种方法，#2 就是C-x b C。

#1 的一种方法是在Icicles 中使用C-0 C-o。它允许您使用完成按名称选择窗口。有问题的命令是icicle-choose-window-by-name。

将两者放在一起，通过 Icicles 您可以使用此代码。然后点击F3 做你想做的事。

 (defun foo ()
   (interactive)
    (call-interactively #'icicle-choose-window-by-name)
    (call-interactively #'switch-to-buffer))

 (global-set-key [f3] 'foo)

如果您不想使用冰柱，还有其他方法可以选择窗口。 This is the place to start，在查找有关选择（在其中导航）窗口的信息时。