如何在SAS中计算条件

Question

我有一张表，其中包含从 1 到 11 的事件，变量有 3 种字符，如 HSP、REP、OH。我需要通过创建一个新列作为 OH1、OH2、OH3、OH4 来计算 HSP。每列的描述是

1) 第一个 OH 之前的 HSP 数
2) 第 1 和第 2 OH 之间的 HSP 数量
3) 第 2 和第 3 OH 之间的 HSP 数量
4) 第 3 和第 4 OH 之间的 HSP 数量

SLN     EV1 EV2 EV3 EV4 EV5 EV6 EV7 EV8 EV9 EV10 EV11
120132  HSP OH  HSP HSP REP OH  HSP HSP HSP OH  REP
120135  OH  HSP HSP HSP HSP OH  HSP HSP HSP HSP OH
120200  OH  HSP OH  HSP HSP OH  HSP OH  HSP OH  HSP
120251  OH  HSP 
120318  HSP OH  HSP HSP HSP OH  HSP HSP HSP HSP HSP
120327  OH  HSP HSP HSP HSP OH  HSP HSP HSP HSP HSP
120509  HSP OH  HSP HSP HSP HSP OH  HSP HSP OH  HSP
120510  HSP HSP     

如果根本没有后面的 'OH' 则设置为缺少 E.g.120327: oh1=0, oh2=4, oh3=。

Answer 1

这是一种使用数组而不做字符串连接和解析的方法

data counts;
input SLN EV1 $ EV2 $ EV3 $ EV4 $ EV5 $ EV6 $ EV7 $ EV8 $ EV9 $ EV10 $ EV11 $;
array EV[11] ;
array OH[4];

next = 1;
do i=1 to 4;
    oh[i] = 0;
end;
do i=1 to 11;
    if next > 4 then leave;
    if ev[i] = "HSP" then
        OH[next] = OH[next] + 1;
    else if ev[i] = "OH" then
        next = next + 1;
end;

datalines;
120132  HSP OH  HSP HSP REP OH  HSP HSP HSP OH  REP
120135  OH  HSP HSP HSP HSP OH  HSP HSP HSP HSP OH
120200  OH  HSP OH  HSP HSP OH  HSP OH  HSP OH  HSP
120251  OH  HSP REP HSP REP HSP HSP HSP HSP OH  HSP
120318  HSP OH  HSP HSP HSP OH  HSP HSP HSP HSP HSP
120327  OH  HSP HSP HSP HSP OH  HSP HSP HSP HSP HSP
120509  HSP OH  HSP HSP HSP HSP OH  HSP HSP OH  HSP
120510  HSP OH  HSP REP HSP HSP OH  HSP HSP HSP HSP
;
run;

Answer 2

这应该可行：

data want;
  set have;
  x1=cat(of ev1-ev11);
  x2=' '||tranwrd(x1,'OH','|');
  array oh oh1-oh4;
  if index(x2,'|') then
  do i = 1 to 4;
    oh[i]=count(scan(x2,i,'|'),'HSP');
  end;
  else call missing(of oh1-oh4);
  drop x1-x2 i;
run;

x1 将代码连接成一个长字符串。 x2 增加了管道，使得 oh 计算中的扫描功能成为可能，它还在前面添加了一个空格，如果第一个代码是 'OH'，它还允许 oh1 等于零

如果您需要将其扩展到 11 个 ev 列和 4 个 OH 计数之外，您可以使用数组或宏。

编辑：为 OH 计数添加了数组。

如果没有找到OH，则编辑为空值。

修订

data counts;
input SLN EV1 $ EV2 $ EV3 $ EV4 $ EV5 $ EV6 $ EV7 $ EV8 $ EV9 $ EV10 $ EV11 $;
array EV[11] ;
array OH[4];
chk=0;
next = 1;
do i=1 to 4;
    oh[i] = 0;
end;
do i=1 to 11;
    if next > 4 then leave;
    if ev[i] = "HSP" then
        OH[next] = OH[next] + 1;
    else if ev[i] = "OH" then do;
        next = next + 1;
            chk+1;
        end;
    end;
    if chk<4 then do j=chk+1 to 4;
      oh[j]=.;
    end;



datalines;
120132  HSP OH  HSP HSP REP OH  HSP HSP HSP OH  REP
120135  OH  HSP HSP HSP HSP OH  HSP HSP HSP HSP OH
120200  OH  HSP OH  HSP HSP OH  HSP OH  HSP OH  HSP
120251  OH  HSP REP HSP REP HSP HSP HSP HSP OH  HSP
120318  HSP OH  HSP HSP HSP OH  HSP HSP HSP HSP HSP
120327  OH  HSP HSP HSP HSP OH  HSP HSP HSP HSP HSP
120509  HSP OH  HSP HSP HSP HSP OH  HSP HSP OH  HSP
120510  HSP OH  HSP REP HSP HSP OH  HSP HSP HSP HSP
;
run;