在 SAS 中使用 Compress 和 Put/Input 函数

Question

我这里有这两个数据集：

data ONE;    
  input ID LastName $ FirstInit $ 1.;    
  datalines;                         
509182793 Smith C                   
319861601 Williams J                    
345121778 Connor F                  
480863211 King L                    
907636280 Franklin D                    
729082859 Monroe T                  
835688938 Hall K
  ;                 
run;    

data TWO; 
  input ID $ 11. State $ 2.;
  datalines;
334-99-5246 TX
480-86-3211 MD
449-55-9407 VA
345-12-1778 GA
907-63-6280 NY
790-09-9813 WY
319-86-1601 FL
  ;
run;

我有两个问题： 1) 你将如何使用COMPRESS 创建一个新的字符变量“ncv”并将 ncv 的值设置为删除连字符的字符变量 ID 的值？这是我的尝试：

data TWO_NUMERIC;
  set TWO;
  ncv=COMPRESS(TWO, "+-", "d");
run;

2) 如何使用PUT/INPUT 将 ncv 转换为数值以创建数值变量“newncv”

data TWO_NUMERIC;
  set TWO;
  put(TWO,z6.);
run;

从这两个问题开始，我从 DATA 步和 SET 语句开始：

data TWO_NUMERIC;
  set TWO;
run;

我查看了 SAS 9.2 的帮助页面，但在他们的示例代码中使用这两个语句似乎让我感到困惑。

Answer 1

好的，我本来想说的是 RTM，但在这种情况下不清楚，至少在我看来不是。

您对压缩的错误是第一个参数应该是变量，在这种情况下是 ID，而不是数据集 TWO。此外，您只需在列表中指定 -，而不是 +，除非您认为变量中也可能有 +。添加修饰符 D，指定将数字添加到删除列表，这与您想要的相反。

与 PUT/INPUT 类似的概念，引用变量并确保使用正确的函数，在这种情况下，输入将其转换为数字。

Data two_numeric;
   set two;

   ncv=COMPRESS(ID, "-");
   ncv_num=input(ncv, 12.);
run;

Answer 2

压缩可以有多种使用方式，一种是上面@Reeza描述的，另一种是使用“k”修饰符，意思是“保持”，如下图，

data TWO_NUMERIC;
  set TWO;
  ncv_d=COMPRESS(ID," ", "kd"); * kd means keep-digits, your code had TWO which is a dataset name;
  ncv_n=COMPRESS(ID," ", "kn"); * kd means keep-numbers;

  /* Input Function is used to convert CHAR to NUM        *
   * the best. format applies the nearest matching format */
  newncv=input(ncv_d,best.); 
run;  

我发现有助于解释 K 修饰符的链接是 http://www.amadeus.co.uk/sas-training/tips/1/1/11/the-enhanced-compress-function.php