直接从用户窗体分配变量

Question

我正在尝试添加一些代码来弹出一个用户表单，允许最终用户输入他们特定网站的登录名/密码。这段代码Passing variable from Form to Module in VBA 让我更接近我的目标，但我不确定如何让它按我需要的方式工作。这是我的用户表单的代码。

Private Sub CommandButton1_Click()
UPass = UserForm1.UserID
Unload UserForm1
End Sub

Private Sub CommandButton1_Click()
UID = UserForm1.WavePassword
Unload UserForm1
End Sub

我正在使用以下代码登录网站。

    Public Sub Connect_To_Wave()
    Dim Dasboard As Worksheet
        Set Dashboard = ActiveWorkbook.Worksheets("Dashboard")
    Dim UID As String
        UID = driver.findElementByName("PASSWORD").SendKeys UID
    Dim UPass As String
        UPass = driver.findElementByName("PASSWORD").SendKeys Upass




Set ie = CreateObject("InternetExplorer.Application")
my_url = "url of website - not a variable"

With ie
    .Visible = True
    .Navigate my_url
    .Top = 100
    .Left = 530
    .Height = 700
    .Width = 400

Do Until Not ie.Busy And ie.readyState = 4
    DoEvents
Loop

End With

ie.Document.getElementById("txtLoginUsername").Value = ""
ie.Document.getElementById("txtLoginPassword").Value = ""
ie.Document.getElementById("txtLoginUsername").Value = UID
ie.Document.getElementById("txtLoginPassword").Value = UPass
ie.Document.getElementById("btnLogin").Click

Do Until Not ie.Busy And ie.readyState = 4
    DoEvents
Loop
End Sub

我遇到的问题是我在 uid/upass 变量上收到“预期语句结束”错误。如何正确让用户表单将输入直接传递给变量，以便变量可用于登录网站？如果有更好的方法，我完全愿意改变方法。

Answer 1

这不可能编译：

Private Sub CommandButton1_Click()
UPass = UserForm1.UserID
Unload UserForm1
End Sub

Private Sub CommandButton1_Click()
UID = UserForm1.WavePassword
Unload UserForm1
End Sub

一个过程不能存在两次。重命名您的按钮OkButton，添加一些CancelButton 并重写表单的代码隐藏，如下所示：

Option Explicit
Private cancelling As Boolean

Public Property Get UID() As String
    UID = UserID.Text
End Property

Public Property Get PWD() As String
    PWD = WavePassword.Text
End Property

Public Property Get IsCancelled() As Boolean
    IsCancelled = cancelling
End Property

Private Sub OkButton_Click()
    Me.Hide
End Sub

Private Sub CancelButton_Click()
    cancelling = True
    Me.Hide
End Sub

Private Sub UserForm_QueryClose(Cancel As Integer, CloseMode As Integer)
    If CloseMode = VbQueryClose.vbFormControlMenu Then
        cancelling = True
        Me.Hide
    End If
End Sub

注意OkButton、CancelButton 和QueryClose 处理程序只隐藏表单，因此调用代码仍然可以读取IsCancelled、UID 和PWD 属性价值观。

调用代码可以做到这一点——假设用户窗体被重命名为LoginPrompt：

Public Sub DownloadStuff()
    With New LoginPrompt
        .Show vbModal
        If .IsCancelled Then Exit Sub
        ConnectToWave .UID, .PWD
    End With
End Sub

最后，ConnectToWave 过程，接受用户的输入：

Private Sub ConnectToWave(ByVal userID As String, ByVal password As String)
    ' there, you got your values from the form - now use them!
End Sub

Answer 2

我不确定driver 是什么，但这个说法是错误的

UID = driver.findElementByName("PASSWORD").SendKeys UID as Sendkeys 是一种方法，因此在尝试分配返回值时需要使用括号。

试试这个：

UID = driver.findElementByName("PASSWORD").SendKeys(UID)

Answer 3

这个：

Dim UID As String
    UID = driver.findElementByName("PASSWORD").SendKeys UID
Dim UPass As String
    UPass = driver.findElementByName("PASSWORD").SendKeys Upass

应该是：

Dim UID As String
    UID = driver.findElementByName("PASSWORD").SendKeys(UID)
Dim UPass As String
    UPass = driver.findElementByName("PASSWORD").SendKeys(Upass)

---

如果您调用的函数没有将任何内容分配回一个值，那么您不需要使用括号，但如果它正在为变量分配内容，那么您需要使用上述语法。

Foo() 是一个函数，Bar 是一个变量

'// Not assigning a value
Foo Bar

'// Assigning a value
someVar = Foo(Bar)

Answer 4

要完成您想要的，您必须在模块顶部创建一个全局变量。我怀疑你正在使用 ArcObjects，所以废弃整个 driver.findElementByName 的东西。此外，您已经正确设置了用户名和密码字段的值（此位：ie.Document.getElementById("txtLoginUsername").Value = UID），因此不需要任何SendKeys 方法。

你需要的是在你的代码模块的最顶部这样的东西：

Option Explicit
Public UID as String
Public UPass as String