如何使用 perl 隐藏击键并将其发送到命令提示符窗口？

Question

我已经使用 Win32::GUItest 编写了一个 perl 脚本来将击键发送到 windows 中的命令提示符窗口，现在当我的脚本运行时，它使用 perl 中的系统函数并打开一个新的 cmd.exe 文件并发送击键给它。直到这里一切正常，但我不希望该命令提示符窗口可见并且用户手动运行脚本。我希望将击键发送到后台的 cmd.exe 窗口中。我想使用 schtasks 使用 windows 64 位服务器来安排脚本。

请不要建议我使用Proc::Background、Win32::Service 和Win32::Daemon，除非您真的尝试过这项任务，您可以使用它们。

Answer 1

我认为您可以使用Win32::Console 控制控制台。

我没有这方面的经验，但文档听起来很有希望：因为有一个 Display() 函数，我假设控制台默认是隐藏的。

Answer 2

您需要向相关窗口发送WM_CHAR 或WM_UNICHAR 消息，而不是依赖窗口处于活动状态并处于前台。

这个例子似乎对我有用。当密钥被发送到在cmd.exe 窗口中运行的links 时，我能够切换到其他应用程序。当我写完一封电子邮件时，链接已经导航到example.com。

#!/usr/bin/env perl

use strict; use warnings;
use Encode qw(encode);
use Time::HiRes qw( usleep );
use Win32::GuiTest qw(SendMessage ShowWindow WaitWindow);

use constant WM_CHAR => 0x0102;
use constant SW_HIDE => 0;
use constant SW_SHOW => 5;

system qw(start links);

my $hwnd = WaitWindow('Links', 5);

ShowWindow $hwnd, SW_HIDE;

send_message($hwnd, "ghttp://example.com/\r");

ShowWindow $hwnd, SW_SHOW;

send_message($hwnd, "q\r", 3_000_000);

sub send_message {
    my ($hwnd, $msg, $delay) = @_;

    $delay ||= 25_000;
    my @keys = encode_keys($msg);

    for my $key (@keys) {
        SendMessage $hwnd, WM_CHAR, $key, 0;
        usleep $delay;
    }
    return;
}

sub encode_keys {
    my ($msg) = @_;
    map ord, map encode('UTF16-LE', $_), split //, $msg;
}