excel vba：特殊类型 - 作为函数参数的函数

Question

VBA 中的函数没有特殊类型。我很难理解如何将函数作为参数添加到 Excel VBA 中的函数。

我想要完成的是这样的：

function f(g as function, x as string) as string
        f = g(x)
end function

目前，我有一组小函数，它们都在重复自己，但只调用一个特定函数。

Answer 1

从您的代码中，函数 g 接受一个字符串参数并返回一个字符串。我建议你创建一个名为 IStringFunction 的类模块来定义所有函数都支持的接口，因此：

类模块：IStringFunction

Public Function Evaluate(ByVal s As String) As String
End Function

然后，创建几个实现该接口的示例函数：

类模块：HelloStringFunction

Implements IStringFunction

Public Function IStringFunction_Evaluate(ByVal s As String) As String
    IStringFunction_Evaluate = "hello " & s
End Function

类模块：GoodbyeStringFunction

Implements IStringFunction

Public Function IStringFunction_Evaluate(ByVal s As String) As String
    IStringFunction_Evaluate = "goodbye " & s
End Function

...最后，一些测试代码来执行这些功能：

（标准）模块：测试

Sub Test()

    Dim oHello As New HelloStringFunction
    Dim oGoodbye As New GoodbyeStringFunction

    MsgBox Evaluate(oHello, "gary")
    MsgBox Evaluate(oGoodbye, "gary")

End Sub

Private Function Evaluate(ByVal f As IStringFunction, ByVal arg As String) As String
    Evaluate = f.Evaluate(arg)
End Function

请注意，实现接口的类必须具有如上例中名为 <Interface>_<Method> 的方法，而不仅仅是您所期望的 <Method>。

在此处下载simple demo 或intermediate demo

Answer 2

由于 VBA 植根于交互式语言，它始终具有执行文本的能力：

function f(g as string, x as string) as string
        f = application.run(g,x)
end function

MyStringA = f("functionA",string1)
MyStringB = f("functionB",string1)

编辑添加： 我认为在当前版本的 Excel 中，应用程序 (Excel) 只能“运行”您可以在电子表格单元格中显示的内容。所以这意味着函数，而不是子例程。要执行子例程，请将其包装在函数包装器中：

function functionA(x as string)
    Call MySubA(x)
end function

Answer 3

可以将函数作为参数传递，并准确获得您所追求的行为，但这有点hacky。这是通过利用类的默认属性来实现的，

创建一个包含您的函数的类myFunction

Public Function sayHi(ByVal s As String) As String
    sayHi = "Hi " & s
End Function

导出它，然后在文本编辑器中打开 .cls 文件

您应该在文件中的某处看到定义函数的行

Public Function sayHi(ByVal s As String) As String

在它下面，添加行Attribute Value.VB_UserMemId = 0，现在它看起来像这样：

Public Function sayHi(ByVal s As String) As String
Attribute Value.VB_UserMemId = 0
    sayHi = "Hi " & s
End Function

您在这里所做的是将sayHi 标记为班级的default property。现在可以通过类对象单独调用函数class(args)，而不是class.function(args)

保存修改后的文件并将其导入您的 VBA 项目

测试模块

Sub test()
    Dim parameterFunction As Object         'this is what we'll be passing to our routine
    Set parameterFunction = New myFunction  'create instance of the function object
    MsgBox f(parameterFunction, "Greedo")
End Sub

Function f(ByVal g As Object, ByVal x As String) As String
        f = g(x)
End Function

*NB，这样你可以传递任何函数；但您可以改为指定 ByVal g As IStringFunction 以仅获取具有正确接口的子集，如 Gary McGill's answer