VBA 中的 WorksheetFunction.IsNumber() 和 IsNumeric() 有什么区别？

Question

在 VBA 中使用这两个函数有什么不同？使用一个比另一个有速度优势吗？

Application.WorksheetFunction.IsNumber(myVar)
IsNumeric(myVar)

Answer 1

IsNumeric是位于VBA.Information模块中的VBA标准库函数，如IsArray、IsDate、IsError、Err、VarType等：

作为 VBA 标准库的一部分，无论宿主应用程序如何，它都能正常工作：可以安全地假定标准库存在于运行 VBA 的机器上。

另一方面，Application.WorksheetFunction.IsNumber 位于 Microsoft Excel 对象模型库中：

因此，代码只有在引用 Excel 类型库时才能工作。如果您已经在 Excel 中，那不是问题。但是，如果您在 Word 中，并且想要使用在给定的 String 是数字时返回 Boolean 的函数，您不想仅仅为此引用整个 Excel 类型库。

WorksheetFunction 接口是通往 Excel 计算引擎的门户：有了它，您可以编写 VBA 代码，现在可以使用 INDEX/MATCH 来处理精心制作的纯 VBA 数组 - 这非常棒。但不能保证 Excel 的计算引擎的工作方式与 VBA 的工作方式完全相同。如果你想遵守 Excel 的规则，请使用WorksheetFunction。

我可能会认为 VBA.Information.IsNumeric 比 Excel.WorksheetFunction.IsNumber 快：我可能是错的，但似乎只有 VBA 标准库涉及更少的移动部件。

但唯一的办法是：

你有两匹马 - 与它们比赛！

;-)

Answer 2

TL;DR 除非您有特定的理由为函数使用 Excel 的语义（即复制它将在单元格中给出的结果，否则如果您关心性能，请不要使用 IsNumber .

首先，结果（和性能）会根据传递给函数的数据类型而有所不同。如果您直接从工作表中提取值，您必须意识到 Excel 会根据您访问它的方式以不同的方式转换值：

Public Sub Foo()
    Debug.Print IsNumeric("1e12")   'True
    Debug.Print Application.WorksheetFunction.IsNumber("1e12")  'False
    [A1] = "1e12"
    'The next 2 are the same, but the first is an implicit call to .Value
    Debug.Print Application.WorksheetFunction.IsNumber([A1])    'True 
    Debug.Print Application.WorksheetFunction.IsNumber([A1].Value)    'True
    Debug.Print Application.WorksheetFunction.IsNumber([A1].Text)    'False
End Sub

接下来，针对WorksheetFunction 的解引用调用有少量开销，因此我将在下面的基准测试中通过将其包装在With 块中来控制它。还要注意处理字符串和数字之间的性能差异（和返回值 o_O）：

Private Const ITERATIONS As Long = 1000000

Private Sub RunAll()
    Test 1000
    Test "1000"
End Sub

Private Sub Test(testValue As Variant)
    IsNumericBenchMark testValue
    IsNumberBenchMark testValue
End Sub

Private Sub IsNumericBenchMark(inputValue As Variant)
    Dim start As Single, i As Long
    start = Timer
    For i = 1 To ITERATIONS
        IsNumeric inputValue
    Next
    Debug.Print "IsNumeric" & vbTab & Timer - start & vbTab & IsNumeric(inputValue)
End Sub

Private Sub IsNumberBenchMark(inputValue As Variant)
    Dim start As Single, i As Long
    start = Timer
    With WorksheetFunction
        For i = 1 To ITERATIONS
            .IsNumber inputValue
        Next
    End With
    Debug.Print "IsNumber" & vbTab & Timer - start & vbTab & WorksheetFunction.IsNumber(inputValue)
End Sub

结果：

IsNumeric   0.09375     True
IsNumber    5.664063    True
IsNumeric   0.6796875   True
IsNumber    6.796875    False

这是官方的，IsNumber 并不是表现最好的人。