在管理错误时在管道中链接异步休息调用

Question

在之前基于同步调用的question 的基础上，我们如何在以下场景中处理异步方法。

let fetch1 (result: string) : Result<string, string> =
    try
        use request = WebRequest.Create("http://bing.com") :?> HttpWebRequest
        use response = request.GetResponse()
        use reader = new StreamReader(response.GetResponseStream())
        let html = reader.ReadToEnd()
        Ok "success"
    with
        | :? WebException as e ->
        Error "error with the url"

let fetch2 (result: string) : Result<string, string> =
    try
        use request = WebRequest.Create("http://google.com") :?> HttpWebRequest
        use response = request.GetResponse()
        use reader = new StreamReader(response.GetResponseStream())
        let html = reader.ReadToEnd()
        Ok "success"
    with
        | :? WebException as e ->
        Error "error with the url"

let fetch3 (result: string) : Result<string, string> =
     try
         use request = WebRequest.Create("http://invalid.com") :?> HttpWebRequest
         use response = request.GetResponse()
         use reader = new StreamReader(response.GetResponseStream())
         let html = reader.ReadToEnd()
         Ok "success"
     with
         | :? WebException as e ->
         Error "error with the url"

测试

let chain = fetch1 >> Result.bind fetch2 >> Result.bind fetch3

match chain("") with 
| Ok message -> Debug.WriteLine(message)
| Error error -> Debug.WriteLine(error)

尝试

let fetch1 (result: string) :Result<string, string> = async {
    try
        use! request = WebRequest.Create("http://bing.com") :?> HttpWebRequest
        use response = request.GetResponse()
        use reader = new StreamReader(response.GetResponseStream())
        let html = reader.ReadToEnd()
        Ok "success"
    with
        | :? WebException as e ->
        Error "error with the url"
 }

错误

此表达式的类型为“Result”，但此处的类型为“Async'

Answer 1

您应该在此处说明您实际尝试实现的异常处理机制。对于很多事情，只使用普通的 F# 内置异常就可以很好地工作。

您正在使用Result.bind，这是一种实现异常处理行为的方法，如果任何步骤抛出异常，整体计算将失败。这是你想要达到的目标吗？如果是这样，您可以只依靠内置的 F# 异步支持来处理异常，并在调用两个 fetch 函数的异步计算中使用 try .. with。一个最小的例子：

let fetch url = async {
  use wc = new WebClient()
  let! res = wc.AsyncDownloadString(System.Uri(url))
  return res }

let fetchAllOrNothing = async {
  try 
    let! goog = fetch "http://www.google.com"
    let! bing = fetch "http://www.bing.com"
    return Some(goog.Length, bing.Length)
  with _ ->
    return None }

如果您想调用所有 fetch 函数并且仅在所有函数都失败时才失败，那么您需要使用异常处理程序（如您所做的那样）包装各个 fetch 函数，然后选择第一个结果。使用普通的 F# 选项类型，这可以使用 Array.tryPick 来完成：

let fetch url = async {
  try
    use wc = new WebClient()
    let! res = wc.AsyncDownloadString(System.Uri(url))
    return Some res 
  with _ -> 
    return None }

let fetchFirstOne = async {
  let! all = 
    [ fetch "http://www.google.com"
      fetch "http://www.bing.com" ] |> Async.Parallel
  return Array.tryPick (fun x -> x) all }

如果您从 F# 开始，那么开始使用诸如核心 async 函数和选项之类的东西会容易得多 - 一旦您对这些感到满意，就可以考虑使用更复杂的方法。