在 awk 中删除一个变量

Question

我想知道是否可以删除awk 中的变量。对于数组，你可以说delete a[2]，数组a[] 的索引2 将被删除。但是，对于一个变量，我找不到方法。

我得到的最接近的是var="" 或var=0。

但是，不存在的变量的默认值似乎是0 或False：

$ awk 'BEGIN {if (b==0) print 5}'
5
$ awk 'BEGIN {if (!b) print 5}' 
5

所以我也想知道是否可以区分设置为0的变量和未设置的变量，因为它似乎没有：

$ awk 'BEGIN {a=0; if (a==b) print 5}'
5

Answer 1

没有取消设置/删除变量的操作。变量再次变为未设置的唯一时间是在函数调用结束时，当它是一个未使用的函数参数被用作局部变量时：

$ cat tst.awk
function foo( arg ) {
    if ( (arg=="") && (arg==0) ) {
        print "arg is not set"
    }
    else {
        printf "before assignment: arg=<%s>\n",arg
    }
    arg = rand()
    printf "after assignment: arg=<%s>\n",arg
    print "----"
}
BEGIN {
    foo()
    foo()
}

$ awk -f tst.awk file
arg is not set
after assignment: arg=<0.237788>
----
arg is not set
after assignment: arg=<0.291066>
----

因此，如果您想执行一些操作 A，然后取消设置变量 X，然后执行操作 B，您可以使用 X 作为局部变量将 A 和/或 B 封装在函数中。

请注意，默认值是零或空，而不是零或假，因为它的类型是“数字字符串”。

您通过将未设置的变量与 null 和零进行比较来测试它：

$ awk 'BEGIN{ if ((x=="") && (x==0)) print "y" }'
y
$ awk 'BEGIN{ x=0; if ((x=="") && (x==0)) print "y" }'
$ awk 'BEGIN{ x=""; if ((x=="") && (x==0)) print "y" }'

如果您需要删除一个变量，那么您始终可以使用单元素数组：

$ awk 'BEGIN{ if ((x[1]=="") && (x[1]==0)) print "y" }'
y
$ awk 'BEGIN{ x[1]=""; if ((x[1]=="") && (x[1]==0)) print "y" }'
$ awk 'BEGIN{ x[1]=""; delete x; if ((x[1]=="") && (x[1]==0)) print "y" }'
y

但是恕我直言，这会混淆您的代码。

取消设置变量的用例是什么？ var="" 或 var=0 不能用它做什么？

Answer 2

未设置的变量会扩展为 "" 或 0，具体取决于对其进行评估的上下文。

出于这个原因，我会说这是一个偏好问题，取决于变量的使用。

鉴于我们在END 块中使用a + 0（或稍有争议的+a）将可能未设置的变量a 强制为数字类型，我猜你可能会争辩说自然的“空”值为""。

鉴于以下情况，我不确定您在问题中显示的案例是否有太多内容需要阅读：

$ awk 'BEGIN { if (!"") print  }'
5

（"" 是假的，这不足为奇）

$ awk 'BEGIN { if (b == "") print 5 }'
5

（未设置变量的计算结果等于""，与0 相同）