Emacs 中的 Ruby 模式在编译/运行的快捷键中？

Question

我对 Emacs 有所了解，因为我用它在 AUCtex 中写论文。

但是，这一次尝试编写一些简单的 ruby​​ 程序主要是为了学习时，我在 Emacs 中搜索了 Ruby，但找不到我想要的东西。

根据我目前阅读的内容，我知道我正在使用的 Emacs(23.3.5) 具有内置 ruby​​ 模式，它应该支持基本的语法高亮、自动缩进等。但是快捷键怎么样对于调试/运行，类似于Mode Compile?

Answer 1

我建议使用我维护的quickrun.el。

quickrun.el 是执行编辑缓冲区的扩展。 quickrun.el 当然支持许多编程语言和标记语言 它支持 Ruby。

您下载 quickrun.el 以下网址。

https://raw.github.com/syohex/emacs-quickrun/master/quickrun.el

然后您将 quickrun.el 以下设置添加到您的配置文件并评估它（或重新启动 Emacs）。

(add-to-list 'load-path "~/.emacs.d/elisp") ;; If you install quickrun.el to ~/.emacs.d/elisp
(require 'quickrun)

现在您可以使用以下命令来执行当前缓冲区。

M-x quickrun

您可以使用编译当前缓冲区（不执行）。

M-x quickrun-compile-only

如果你经常使用 quickrun 命令，你应该分配键绑定，如下所示。

(global-set-key (kbd "<f7>") 'quickrun)
(global-set-key (kbd "<f8>") 'quickrun-compile-only)

如果您了解有关 quickrun.el 的更多信息，请参阅github page。

谢谢

Answer 2

我建议使用inf-ruby 在 Emacs 中获取 IRB 会话。然后你可以使用例如C-c C-l 调用inf-ruby-load-file 在 IRB 会话中加载缓冲区。

此外，您可能还想使用Flymake 不断地根据ruby -c 检查缓冲区的语法。以下是我从emacs-starter-kit 中获取的 3 个函数：

(defun flymake-ruby-init ()
  (let* ((temp-file (flymake-init-create-temp-buffer-copy
                     'flymake-create-temp-inplace))
         (local-file (file-relative-name
                      temp-file
                      (file-name-directory buffer-file-name))))
    ;; Invoke ruby with '-c' to get syntax checking
    (list "ruby" (list "-c" local-file))))

(defun flymake-ruby-enable ()
  (when (and buffer-file-name
             (file-writable-p
              (file-name-directory buffer-file-name))
             (file-writable-p buffer-file-name)
             (if (fboundp 'tramp-list-remote-buffers)
                 (not (subsetp
                       (list (current-buffer))
                       (tramp-list-remote-buffers)))
               t))
    (local-set-key (kbd "C-c d")
                   'flymake-display-err-menu-for-current-line)
    (flymake-mode t)))

(eval-after-load 'ruby-mode
  '(progn
     (require 'flymake)
     (push '(".+\\.rb$" flymake-ruby-init) flymake-allowed-file-name-masks)
     (push '("Rakefile$" flymake-ruby-init) flymake-allowed-file-name-masks)
     (push '("^\\(.*\\):\\([0-9]+\\): \\(.*\\)$" 1 2 nil 3)
           flymake-err-line-patterns)
     (add-hook 'ruby-mode-hook 'flymake-ruby-enable)))

此外，我使用以下函数来显示 Flymake 错误：

;; Flymake errors at point from Dave Love on gnu.emacs.help:
(defun my-flymake-show-help ()
   (when (get-char-property (point) 'flymake-overlay)
     (let ((help (get-char-property (point) 'help-echo)))
       (if help (message "%s" help)))))

(add-hook 'post-command-hook 'my-flymake-show-help)

以上所有因素共同构成了非常不错的 Ruby Emacs 体验。

Answer 3

您可以从 M-x compile 运行 ruby​​ 程序并使用“ruby -w your_program”。

输出将类似于编译输出，因此您可以单击错误转到该行。

看来mode-compile也支持ruby-mode。