如果其他条件，野牛减少/减少冲突答案

【问题标题】：Bison reduce/reduce conflict if else condition如果其他条件，野牛减少/减少冲突
【发布时间】：2015-02-03 19:18:25
【问题描述】：

我期待 if else 发生 shift/reduce 冲突，但它在 "| IF '(' boolean_statement ')' 块" 行上产生了 reduce/reduce 冲突。

这里有一些信息可能有助于解释以下代码：

BOOL 是用于每行开头的关键字的标记，表示该行是布尔运算
BOOLEAN 是“真”或“假”值

我正在使用此编译器将一种语言转换为 C 代码，该语言可以包含类似 a,b,c=d+2 的语句，相当于 C 中的 a=b=c=d+2；和bool e = f * .N. g + h，相当于e = f && !g || h。

statements:
        statements statement
        | statement
        ;

statement:
        if_statement
        | BOOL variable_list '=' boolean_statement
        | variable_list '=' integer_statement
        ;

if_statement:
        IF '(' boolean_statement ')' block ELSE block
        | IF '(' boolean_statement ')' block
        ;

variable_list:
        variable_list ',' variable
        | variable
        ;

variable:
        STRING 
        | STRING '[' INTEGER ']'
        | STRING '[' STRING ']'
        ;

boolean_statement:
        '(' boolean_statement ')'
        | bval '*' boolean_statement
        | bval '+' boolean_statement
        | bval EQ boolean_statement
        | bval NEQ boolean_statement
        | NOT boolean_statement
        | bval
        ;

bval:
        BOOLEAN   
        | variable
        ;

integer_statement:
        '(' integer_statement ')'
        | value '+' integer_statement
        | value '*' integer_statement
        | value
        ;

value:
        INTEGER        
        | variable
        ;

block:
        statement
        | '{' statements '}'
        ;

这是完整的代码

   %{

    #include <cstdio>
    #include <iostream>
    using namespace std;

    //stuff from flex that bison needs to know about:
    extern "C" int yylex();
    extern "C" int yyparse();
    extern "C" FILE *yyin;
    extern int line_num;

    void yyerror(const char *s);

    %}

    //C union holding each of the types of tokens that Flex could return
    %union { 
            int ival;
            bool bval;
            char const *sval;
    }

    //symbol defination
    %token <sval> STRING;
    %token <sval> NOT
    %token CONSTANT_SECTION
    %token BOOLEAN_SECTION
    %token INTEGER_SECTION
    %token LOGIC_SECTION
    %token TIMER_SECTION
    %token <sval> BOOLEAN
    %token <ival> INTEGER
    %token <ival> HEX 
    %token ENDL 
    %token BOOL
    %token IF
    %token ELSE
    %token EQ NEQ
    %token AND
    %token OR
    %token SUBROUTINE_END
    %token SUBROUTINE_START
    %token DELAY SECONDS HOURS MINUTES MSEC
    %token GOTO
    %token LABEL
    %token CALL
    //end of declaration section
    %%

    logic:
            costants_declarations boolean_declarations integer_declarations timer_declarations logic_statements
            | boolean_declarations integer_declarations timer_declarations logic_statements
            | logic_statements
            ;

    costants_declarations:
            CONSTANT_SECTION constants  
            ;

    constants:
            constants STRING '=' INTEGER    { cout << "const int " << $2 << " = "  << $4 << ";" << endl; }
            | constants STRING '=' HEX      { cout << "const int " << $2 << " = "  << $4 << ";" << endl; }
            | STRING '=' INTEGER            { cout << "const int " << $1 << " = "  << $3 << ";" << endl; }
            | STRING '=' HEX                { cout << "const int " << $1 << " = "  << $3 << ";" << endl; }
            ;

    boolean_declarations:
            BOOLEAN_SECTION booleans       
            ;

    booleans:
            booleans ',' boolean             
            | booleans boolean               
            | boolean                       
            ;        

    boolean:
            STRING '[' INTEGER ']'          { cout << "bool " << $1 << "[" << $3 << "]" << ";" << endl; }
            | STRING '[' STRING ']'         { cout << "bool " << $1 << "[" << $3 << "]" << ";" << endl; }
            | STRING                        { cout << "bool " << $1 << " = true;" << endl; }
            ;

    integer_declarations:
            INTEGER_SECTION integers
            ;

    integers:
            integers ',' integer            
            | integers integer              
            | integer                      
            ;

    integer:
            STRING '[' INTEGER ']'          { cout << "int " << $1 << "[" << $3 << "]" << ";" << endl; }
            | STRING '[' STRING ']'         { cout << "int " << $1 << "[" << $3 << "]" << ";" << endl; }
            | STRING                        { cout << "int " << $1 << " = 0;" << endl; }
            ;

    timer_declarations:
            TIMER_SECTION timers
            ;

    timers:
            timers ',' timer
            | timers timer
            | timer
            ;

    timer:
            STRING                          { cout << "int " << $1 << ";" << endl; }
            ;

    logic_statements:
            LOGIC_SECTION subroutines statements
            ;

    subroutines:
            /* empty */
            | SUBROUTINE_START STRING statements SUBROUTINE_END STRING
            ;

    statements:
            statements statement
            | statement
            ;

    statement:
            if_statement
            | delay_statement
            | GOTO STRING
            | LABEL
            | CALL STRING
            | BOOL variable_list '=' { cout << " = "; } boolean_statement { cout << ";\n"; } 
            | variable_list '=' { cout << " = "; } integer_statement { cout << ";\n"; }
            ;

    if_statement:
            IF '(' { cout << "if("; } boolean_statement ')' { cout << ")" << endl; } block
            | IF '(' { cout << "if("; } boolean_statement ')' { cout << ")" << endl; } block ELSE block
            ;

    delay_statement:
            DELAY '=' INTEGER SECONDS statement 
            ;

    variable_list:
            variable_list ',' { cout << " = "; } variable
            | variable
            ;

    variable:
            STRING                          { cout << $1; }
            | STRING '[' INTEGER ']'        { cout << $1 << "[" << $3 << "]"; }
            | STRING '[' STRING ']'         { cout << $1 << "[" << $3 << "]"; }
            ;

    boolean_statement:
            '('{ cout << "("; } boolean_statement ')'{ cout << ")"; }
            | bval '+' { cout << " || "; } boolean_statement
            | bval OR { cout << " || "; } boolean_statement
            | bval '*' { cout << " && "; } boolean_statement
            | bval AND { cout << " && "; } boolean_statement
            | bval EQ { cout << " == "; } boolean_statement
            | bval NEQ { cout << " != "; } boolean_statement
            | NOT { cout << $1; } boolean_statement
            | bval
            ;

    bval:
            BOOLEAN                          { cout << $1; }
            | variable
            ;

    integer_statement:
            '('{ cout << "("; } integer_statement ')'{ cout << ")"; }
            | value '+'{ cout << " + "; } integer_statement
            | value '*'{ cout << " * "; } integer_statement
            | value
            ;

    value:
            INTEGER                       { cout << $1; }
            | variable
            ;

    block:
            { cout << "{" << endl; } statement { cout << "}" << endl; }
            | '{' { cout << "{" << endl; } statements '}' { cout << "}" << endl; }
            ;

    //end of grammer section
    %%

    int main(int argc, char *argv[]) {

            // default input is stdin
            // if file is given read from it
            if(argc == 2)
            {
                    // open a file handle to a particular file:
                    FILE *myfile = fopen(argv[1], "r");
                    // make sure it's valid:
                    if (!myfile) {
                            cout << "Can't open "<< argv[1] <<" file" << endl;
                            cout << "Usage: " << argv[0] << " <filename>\n";
                            return -1;
                    }
                    // set lex to read from it instead of defaulting to STDIN:
                    yyin = myfile;
            }
            else if(argc != 1)
            {
                    cout << "Usage: " << argv[0] << " <filename>\n";
                    cout << "Usage: " << argv[0] << endl;
                    return -1;
            }

            // parse through the input until there is no more:
            do 
            {
                    yyparse();
            } while (!feof(yyin));
    }

    void yyerror(const char *s) {
        cout << "Parse error on line " << line_num << "!  Message: " << s << endl;
        // might as well halt now:
        exit(-1);
    }

【问题讨论】：

如果您切换 if 定义的顺序（执行 ELSE 一秒钟），您会收到 shift/reduce 错误吗？
@MichaelWelch 我仍然得到错误，但无论这两个语句的顺序如何，都会减少/减少。
@Ruturaj：请显示您的整个野牛输入，包括% 定义，并确保您正在复制精确的文件。由于boolean_statement 规则中未引用的+ 和*，您提供的那个会引发野牛语法错误。一旦我解决了这个问题，野牛只给了我预期的移位/减少冲突，所以我得出结论，你实际使用的文件是不同的。
@rici 我在上一个问题的末尾添加了我的整个代码。对不起，该语言使用两种类型的和或符号，*/+ 或 &&/||。这就是为什么我删除了一些垃圾并忘记添加引号的原因。
@Ruturaj：谢谢，这样回答起来容易多了。

标签： compiler-construction bison

【解决方案1】：

问题不在于IF 语句。这是if_statement 的两个作品中的中间规则操作 (MRA)：

if_statement:
          IF '(' { cout << "if("; } boolean_statement ')' { cout << ")" << endl; } block
        | IF '(' { cout << "if("; } boolean_statement ')' { cout << ")" << endl; } block ELSE block
        ;

诸如{ cout << "if("; } 之类的中间规则操作被转换为具有唯一名称的空非终结符。实际上，上述产生式变成了以下内容：

if_statement:
          IF '(' @3 boolean_statement ')' @4 block
        | IF '(' @5 boolean_statement ')' @6 block ELSE block
        ;

@3: %empty { cout << "if("; }        ;
@4: %empty { cout << ")" << endl; }  ;
@5: %empty { cout << "if("; }        ;
@6: %empty { cout << ")" << endl; }  ;

在上面，@3 和 @5 是相同的（@4 和 @6 也是如此），但 bison 不会检查它；每个 MRA 都被认为是独一无二的。这会导致 reduce/reduce 冲突，因为一旦解析器读取了 if (，它就需要先减少 @3 或 @5 之一移动下面的标记，不管那个标记可能是什么，但是下一个标记没有给出关于 else 是否最终会出现的任何线索。（两个产品都以boolean_statement 继续，所以下面的标记无论哪种情况，都可以是FIRST(boolean_statement) 中的任何标记。）

冲突以@3（文本上较早的非终端）解决的事实意味着@5永远不能减少，并且bison提供了一个警告。（至少，我的野牛版本做到了。）

这是 MRA 的一个经典问题，非常普遍，因此需要在 bison manual 中添加一个部分。

在这种情况下，您可以简单地通过左分解来解决问题：

if_statement:
      if_then
    | if_then ELSE block
    ;

if_then:
      IF '('                   { cout << "if("; }
      boolean_statement ')'    { cout << ")" << endl; }
      block
    ;

【讨论】：