赋值为 Antlr 语法中的表达式

Question

我正在尝试扩展 the grammar of the Tiny Language 以将赋值视为表达式。因此写是有效的

a = b = 1; // -> a = (b = 1)
a = 2 * (b = 1); // contrived but valid
a = 1 = 2; // invalid

赋值在两个方面不同于其他运算符。它是右关联的（没什么大不了的），它的左边必须是一个变量。所以我就这样改了语法

statement: assignmentExpr | functionCall ...;

assignmentExpr: Identifier indexes? '=' expression;

expression: assignmentExpr | condExpr;

它不起作用，因为它包含一个非 LL(*) 决定。我也试过这个变种：

assignmentExpr: Identifier indexes? '=' (expression | condExpr);

但我遇到了同样的错误。我有兴趣

• 这个具体问题
• 给定一个具有非 LL(*) 判定的文法，如何找到导致问题的两条路径
• 如何解决

Answer 1

我认为你可以像这样改变你的语法来达到同样的效果，而不使用句法谓词：

statement: Expr ';' | functionCall ';'...;

Expr: Identifier indexes? '=' Expr  |  condExpr ;

condExpr: .... and so on;

考虑到这个想法，我修改了 Bart 的示例：

grammar TL;

options {
  output=AST;
}

tokens {
  ROOT;
}

parse
  :  stat+ EOF -> ^(ROOT stat+)
  ;

stat
  :  expr ';' 
  ;

expr
  : Id Assign expr -> ^(Assign Id expr)

  | add
  ;

add
  :  mult (('+' | '-')^ mult)*
  ;

mult
  :  atom (('*' | '/')^ atom)*
  ;

atom
  :  Id
  |  Num
  |  '('! expr ')' !
  ;

Assign  :   '=' ;
Comment : '//' ~('\r' | '\n')* {skip();};
Id      : 'a'..'z'+;
Num     : '0'..'9'+;
Space   : (' ' | '\t' | '\r' | '\n')+ {skip();};

对于输入：

a=b=4;
a = 2 * (b = 1);

你得到以下解析树：

Answer 2

这里的关键是你需要向解析器“保证”在表达式中，前面有满足表达式的东西。这可以使用语法谓词（add 和 mult 规则中的 ( ... )=> 部分）来完成。

快速演示：

grammar TL;

options {
  output=AST;
}

tokens {
  ROOT;
  ASSIGN;
}

parse
  :  stat* EOF -> ^(ROOT stat+)
  ;

stat
  :  expr ';' -> expr
  ;

expr
  :  add
  ;

add
  :  mult ((('+' | '-') mult)=> ('+' | '-')^ mult)*
  ;

mult
  :  atom ((('*' | '/') atom)=> ('*' | '/')^ atom)*
  ;

atom
  :  (Id -> Id) ('=' expr -> ^(ASSIGN Id expr))?
  |  Num
  |  '(' expr ')' -> expr
  ;

Comment : '//' ~('\r' | '\n')* {skip();};
Id      : 'a'..'z'+;
Num     : '0'..'9'+;
Space   : (' ' | '\t' | '\r' | '\n')+ {skip();};

它将解析输入：

a = b = 1;       // -> a = (b = 1)
a = 2 * (b = 1); // contrived but valid

进入以下 AST：