在haskell中实现Read typeclass的实例

Question

我一直在玩一些归纳类型（定义的自然数和对它们的算术运算），但我无法让 Haskell 读取函数工作。

这是我的代码：

data Natural = Zero | Succ Natural
    deriving (Eq, Ord)

instance Enum Natural where
    pred Zero = undefined
    pred (Succ x) = x

    succ x = Succ x

    toEnum 0 = Zero
    toEnum x = Succ (toEnum (x - 1))

    fromEnum Zero = 0
    fromEnum (Succ x) = fromEnum x + 1

instance Num Natural where
    (+) x Zero = x
    (+) x (Succ y) = Succ (x + y)

    (-) Zero (Succ x) = undefined
    (-) x Zero = x
    (-) (Succ x) (Succ y) = x - y

    (*) x Zero = Zero
    (*) x (Succ y) = x * y + x

    abs x = x

    signum Zero = Zero
    signum (Succ x) = Succ Zero

    fromInteger 0 = Zero
    fromInteger x = Succ (fromInteger (x - 1))

instance Show Natural where
    show x = show $ fromEnum x

-- Not working!

instance Read Natural where
    readsPrec x = fromInteger $ (read x) :: Integer

我希望这个表达式有效： naturalNumber = read someStringWithInteger :: Natural，所以我不能只派生 Read 类型类。

我尝试过使用readsPrec 和readPrec，但我只收到不匹配的类型错误。

如何实现 Read 类型类的实例？

Answer 1

您的函数类型错误。您的readsPrec 具有String -> Natural 类型，而您应该使用Int -> String -> [(Natural, String)]。但我们可以调整：

readsPrec p s = [(fromInteger i, s') | (i, s') <- readsPrec p s]

这使用了Integer 的readsPrec 函数。既然你想阅读Integers，那么为了方便使用它是很合适的。

出于对称原因，我建议您在 Show 实例中实现 showsPrec 而不是 show。