标量与列表赋值运算符

Question

请帮我理解下面的sn-ps：

• my $count = @array;
• my @copy = @array;
• my ($first) = @array;
• (my $copy = $str) =~ s/\\/\\\\/g;
• my ($x) = f() or die;
• my $count = () = f();
• print($x = $y);
• print(@x = @y);

Answer 1

符号= 被编译为两个赋值运算符之一：

• 如果= 的左侧 (LHS) 是某种聚合，则使用 列表赋值运算符 (aassign)。
• 标量赋值运算符 (sassign) 用于其他情况。

以下被认为是聚合：

• 括号中的任何表达式（例如(...)）
• 一个数组（例如@array）
• 一个数组切片（例如@array[...]）
• 哈希（例如%hash）
• 一个哈希片（例如@hash{...}）
• 上述任何一个前面都带有my、our 或local

运算符之间有两个区别。

操作数上下文

这两个运算符在计算其操作数的上下文中有所不同。

• 标量赋值在标量上下文中计算它的两个操作数。

  # @array evaluated in scalar context.
  my $count = @array;
  

• 列表赋值在列表上下文中计算它的两个操作数。

  # @array evaluated in list context.
  my @copy = @array;
  

  # @array evaluated in list context.
  my ($first) = @array;
  

返回值

这两个运算符的返回值不同。

• 标量赋值 ...

  • ...在标量上下文中，将其 LHS 作为左值计算。

    # The s/// operates on $copy.
    (my $copy = $str) =~ s/\\/\\\\/g;
    

  • ... 在列表上下文中，将其 LHS 作为左值计算。

    # Prints $x.
    print($x = $y);
    

• 列表赋值...

  • ...在标量上下文中计算其 RHS 返回的标量数。

    # Only dies if f() returns an empty list.
    # This does not die if f() returns a
    # false scalar like zero or undef.
    my ($x) = f() or die;
    

    # $counts gets the number of scalars returns by f().
    my $count = () = f();
    

  • ...在列表上下文中计算其 LHS 作为左值返回的标量。

    # Prints @x.
    print(@x = @y);