Perl JIRA POST 错误“标头必须作为 hashref 呈现”

Question

我正在编写一个 Perl 脚本来发布一个附件到 JIRA 使用 REST::Client 访问API 但我遇到了一个错误。

use REST::Client;

use warnings;
use strict;

use File::Slurp;
use MIME::Base64;

my $user = 'user';
my $pass = 'pass';
my $url  = "http://******/rest/api/2/issue/BugID/attachments";

my $client = REST::Client->new();
$client->addHeader( 'Authorization', 'Basic' . encode_base64( $user . ':' . $pass ) );
$client->addHeader( 'X-Atlassian-Token', 'no-check' );
$client->setHost( $url );

# my %header = ('Authorization' => 'Basic'. encode_base64($user . ':' . $pass),'X-Atlassian-Token' => 'no-check');

my $attachment = "C:\\Folder\\Test.txt";

$client->POST(
    $url,
    'Content_Type' => 'form-data',
    'Content'      => [ 'file' => [$attachment] ]
);

if ( $client->responseCode() eq '200' ) {
    print "Updated\n";
}

# print the result
print $client->responseContent() . "\n";

我得到的错误是

REST::Client 异常：标头必须在 C:\Users\a\filename.pl 第 24 行以 hashref 的形式呈现。

如代码所示，我尝试了不同的方式设置标题，但我仍然得到同样的错误。

如果有其他方法，请建议。

我曾尝试使用 JIRA 模块，但它也会报错。

Answer 1

根据documentation，POST方法：

采用自定义请求标头的可选正文内容和 hashref。

你需要把你的标题放在一个 hashref 中，例如：

$client->POST($url, $content, {
    foo => 'bar',
    baz => 'qux'
});

---

但是...您似乎希望 REST::Client 使用 HTTP::Request::Common 来构造一个多部分/表单数据请求。不幸的是，情况并非如此，因此您必须手动构建内容。

您可以像这样直接使用 HTTP::Request::Common：

use strict;
use warnings 'all';
use 5.010;

use HTTP::Request::Common;
use REST::Client;

my $client = REST::Client->new;
my $url = 'http://www.example.com';

my $req = POST($url,
    Content_Type => 'form-data',
    Content      => [ file => [ 'foo.txt' ] ]
);

$client->POST($url, $req->content(), {
    $req->headers->flatten()
});

但这有点令人费解；我建议放弃 REST::Client 并改用LWP::UserAgent。 REST::Client 只是 LWP::UserAgent 的一个瘦包装器，具有一些便利功能，例如为所有请求添加默认主机。在这种情况下，它只是碍事，我认为不值得麻烦。

Answer 2

来自文档：

POST ($url, [$body_content, %$headers])

而你正在做：

$client->POST(
    $url,
    'Content_Type' => 'form-data',
    'Content'      => [ 'file' => [$attachment] ]
);

所以 - 传递一个标量列表，最后是一个 arrayref。

也许你想要这样的东西：

$client->POST(
    $url,
    $attachment,
    { 'Content-Type' => 'form-data' }
);

注意{} 为标头构造一个匿名散列。

虽然您可能想要打开并包含“附件”，因为REST::Client 中没有关于打开文件并自动发送它们的内容。