用于 S3 存储桶的 Terraform AWS 可选日志记录

Question

我正在尝试使用链接中示例中的 terraform 创建 S3 存储桶 https://www.terraform.io/docs/providers/aws/r/s3_bucket.html 我已经创建了一个 S3 模块。

我面临的问题是，对于某些存储桶，我不想启用日志记录。 这如何在 terraform 中实现。

 logging {
        target_bucket = "${aws_s3_bucket.log_bucket.id}"
        target_prefix = "log/"   
}

对 target_bucket 和 target_prefix 使用空字符串会导致 terraform 尝试创建 target_bucket。

另外，我正在尝试使用一个模块。

Answer 1

使用 terraform 0.12+ 中更新的动态块支持，如果我们想要像这样记录，我们会传递一个包含记录设置的单项数组：

variable "logging" {
  type        = list
  default     = []
  description = "to enable logging set this to [{target_bucket = 'xxx' target_prefix = 'logs/'}]"
}

resource "aws_s3_bucket" "s3bucket" {
  dynamic "logging" {
    for_each = [for l in var.logging : {
      target_bucket = l.target_bucket
      target_prefix = l.target_prefix
    }]
    content {
      target_bucket = logging.value.target_bucket
      target_prefix = logging.value.target_prefix
    }
  }
}

Answer 2

会飞。 如果您想将日志记录的值设为可选，请首先将您的模块设为 aws_s3_bucket.tf：

resource "aws_s3_bucket" "b" {
  bucket = "my-tf-test-bucket"
  acl    = "private"

  logging = "${var.logging}"
}

variable "logging" {
  type    = "list"
  default = []
}

然后在子文件夹example中添加您的模板module.tf：

module "s3" {
  source = "../"

  logging = [
    {
      target_bucket = "loggingbucketname"
      target_prefix = "log/"
    },
  ]
}

provider "aws" {
  region  = "eu-west-1"
  version = "2.4.0"
}

这是您的具有日志记录的版本。

接下来修改你的 module.tf 看起来像

  module "s3" {
      source = "../"
   }

    provider "aws" {
      region  = "eu-west-1"
      version = "2.4.0"
    }

那是你没有的版本。这适用于： Terraform v0.11.11 + provider.aws v2.4.0

更新 这是 v0.12.5 的答案。 模块现在是：

resource "aws_s3_bucket" "b" {
  bucket = "my-tf-test-bucket"
  acl    = "private"

  logging {
    target_bucket = var.logging["target_bucket"]
    target_prefix = var.logging["target_prefix"]
  }
}

variable "logging" {
  type=map
  default={
      target_bucket = ""
      target_prefix = ""
  }
}

使用带有日志记录的模块变为（您的模块路径可能不同）：

module "s3" {
  source = "../"
  logging={
    target_bucket = aws_s3_bucket.log_bucket.id
    target_prefix = "log/"
  }
}

provider "aws" {
  region  = "eu-west-1"
  version = "2.34.0"
}

resource "aws_s3_bucket" "log_bucket" {
  bucket = "my-tf-log-bucket"
  acl    = "private"
}

和没有：

module "s3" {
  source = "../"
}

provider "aws" {
  region  = "eu-west-1"
  version = "2.34.0"
}