SELECT FROM DB_TABLE with left join where column from join table

Question

我想创建一个左连接多个表的选择。

在下面的代码中，我只需要选择表EKPO 的行，其中列EBELN = 变量lv_ebeln。但是一旦我将此条件添加到WHERE，我就会收到以下语法错误：

“SELECT LIST”列表中的元素必须用逗号分隔。

那么，有没有办法添加这个条件呢？

DATA: BEGIN OF wa_itab,
        gjahr TYPE rseg-gjahr,
        ebelp TYPE ekpo-ebelp,
      END OF wa_itab,
      itab     LIKE TABLE OF wa_itab,
      lv_belnr TYPE rseg-belnr,
      lv_ebeln TYPE ekpo-ebeln.

SELECT rseg~gjahr ekpo~ebelp FROM rseg
  LEFT JOIN ekpo ON rseg~ebeln = ekpo~ebeln AND rseg~ebelp = ekpo~ebelp
  INTO (wa_itab-gjahr, wa_itab-ebelp )
  WHERE rseg~belnr = lv_belnr 
    AND ekpo~ebeln = lv_ebeln. " <=== SYNTAX ERROR because of this line

  ...
  " some other code
  ...

  APPEND wa_itab TO itab.
ENDSELECT.

Answer 1

语法错误信息有误导性，逗号不需要，因为问题与OpenSQL strict mode无关。

真正的错误是，在左外连接中，右表EKPO 上的条件在WHERE 中不被接受，因为如果连接结果只有左表RSEG 中的某些行，则列来自右表的EKPO 将具有值null，因此基于右表列的条件为假并且未选择行，使得左外连接的行为类似于内连接。

• 要么使用带有WHERE 中条件的内连接（你不想要的）。
• 或者您保留左外连接并将条件移动到ON 连接条件，如下所示。

代码：

SELECT rseg~gjahr ekpo~ebelp FROM rseg
  LEFT JOIN ekpo ON rseg~ebeln = ekpo~ebeln 
                AND rseg~ebelp = ekpo~ebelp
                AND ekpo~ebeln = lv_ebeln " <=== move it here
  INTO (wa_itab-gjahr, wa_itab-ebelp )
  WHERE rseg~belnr = lv_belnr.

---

PS：我在 ABAP 文档中没有找到正式解释它的参考资料，除了有这个close example：

SELECT s~carrid, s~carrname 
   FROM scarr AS s 
   LEFT OUTER JOIN spfli AS p ON s~carrid   =  p~carrid 
                              AND p~cityfrom = @cityfr  " <=== not in the WHERE
   WHERE p~connid IS NULL 
   ORDER BY s~carrid, s~carrname 
   INTO TABLE @DATA(itab).