如何访问路径集合中的节点对象？ （两个或多个节点的路径）

Question

我有一个图表，其中一些节点是由于应用程序中的错误而创建的。 我想删除那些节点（它们代表一个日志），但我不知道如何循环遍历这些节点。

我不知道如何访问路径集合中的节点，我需要这样做才能将一个节点与另一个节点进行比较。

match (o:Order{id:123})
match (o)-[:STATUS_CHANGE*]->(l:Log)-[:STATUS]->(os:OrderStatus)

with collect((l:Log)-[:STATUS]->(os:OrderStatus)) as logs

我想访问路径中的每个节点以执行比较。每个订单通常有 5 或 6 个 (l)-[:STATUS]->(os)。

如何访问每条路径的 (l) 和 (os) 节点，以比较它们的属性？

例如，如果我在其中一个订单中有此路径集合：

(log1)-[:STATUS]->(os1)

(log2)-[:STATUS]->(os2)

(log3)-[:STATUS]->(os3)

(log4)-[:STATUS]->(os2)

(log5)-[:STATUS]->(os4)

所以，从上面的路径集合中，我想分离删除（log4），因为（os2）节点低于前一个（os3）节点，应该更大。

然后，我想将 (log3) 附加到 (log5)

---

注意：每个 (os) 节点都有一个表示“状态”的 id，从 1 到 5。此外，(log) 节点按创建的日期时间排序。

---

知道如何做到这一点吗？提前谢谢你们！

---

---

编辑

我没有提到我遇到的其他一些情况。这是其中之一：

根据@cybersam 的回答，我找到了解决方法。

我必须运行2个单独的查询才能使其工作，但原理是一样的，如下：

建立新的关系：

MATCH(o:Order)-[:STATUS_CHANGE*]->(l:Log)-[:STATUS]->(os:OrderStatus)
WHERE SIZE((o)-[:STATUS_CHANGE*]->()-[:STATUS]->(os)) >= 1
WITH o, os, COLLECT(l)[0] AS keep
WITH o, collect(keep) AS k
FOREACH(i IN range(0,size(k)-1)   | 
FOREACH(a IN [k[i]]               | 
FOREACH(b IN [k[i+1]]             | 
FOREACH(c IN CASE WHEN b IS NOT NULL THEN [1] END | MERGE (a)-[:STATUS_CHANGE]->(b) ))));

删除超出的节点：

MATCH(o:Order)-[:STATUS_CHANGE*]->(l:Log)-[:STATUS]->(os:OrderStatus)
WHERE (os)<-[:STATUS]-()-[:STATUS_CHANGE*]->(l)-[:STATUS]->(os)
WITH o, os, COLLECT(l) AS exceed
UNWIND exceed AS del
detach delete del;

此查询适用于所有场景。

Answer 1

假设您的所有错误都遵循相同的模式（不需要的 Log 节点始终引用“旧”OrderStatus），这可能对您有用：

MATCH (o:Order{id:123})-[:STATUS_CHANGE*]->(l:Log)-[:STATUS]->(os:OrderStatus)
WHERE SIZE(()-[:STATUS]->(os)) > 1
WITH os, COLLECT(l) AS logs
UNWIND logs[1..] AS unwanted
OPTIONAL MATCH (x)-[:STATUS_CHANGE]->(unwanted)-[:STATUS_CHANGE]->(y)
DETACH DELETE unwanted
FOREACH(ignored IN CASE WHEN x IS NOT NULL THEN [1] END | CREATE (x)-[:STATUS_CHANGE]->(y))

这个查询：

• 查找（按顺序）具有多个STATUS 关系的所有相关OrderStatus 节点。
• 使用aggregating functionCOLLECT 收集（按顺序）与每个OrderStatus 节点相关的Log 节点。
• 使用UNWIND logs[1..] 获取单个不需要的Log 节点。
• 在删除不需要的节点后，使用 OPTIONAL MATCH 获取可能需要连接在一起的 2 个节点。
• 使用DETACH DELETE 删除每个不需要的节点及其关系。
• 使用FOREACH 将可能由OPTIONAL MATCH 发现的节点对连接在一起。