Neo4j 模式非规范化

Question

在我的 Neo4j 应用程序中，我有一个产品、产品特性和投票列表（具有双倍权重），每个产品都具有特定特性。

为了按特征列表的平均投票权重对产品列表进行排序，我需要执行一个复杂的运行时 Cypher 查询，该查询将计算每个产品特征列表的平均权重总和。

这是我当前的 Cypher 查询：

MATCH (parentP:Product)-[:CONTAINS]->(childP:Product)
WHERE id(parentP) = {productId}
WITH childP
OPTIONAL MATCH (p:Product)<-[:VOTED_FOR]-(v:Vote)-[:VOTED_ON]->(c:Characteristic)
WHERE id(p) = id(childP) AND id(c) IN {characteristicIds}
WITH childP, c, avg(v.weight) as weight
RETURN childP AS product, sum(weight) as weight
ORDER BY weight DESC

我知道 Neo4j 的图形遍历速度非常快，但对于聚合（求和、计数、平均等）却没有那么好。我的系统可以为每个产品的每个特征提供大量投票列表。

请帮助我对这种结构进行去规范化，以避免因大量投票而出现任何性能问题。

Brian 查询的 PROFILE 输出：

Cypher 版本：CYPHER 2.2，规划器：COST。 1482 毫秒内总共 374933 次 db 命中。

Answer 1

我不知道我会说 Neo4j 不适合聚合。您可以通过在第二场比赛中特别包含您的 childP 来帮助它节省一些工作：

MATCH (parentP)-[:CONTAINS]->(childP:Product)
WHERE id(parentP) = {productId}
OPTIONAL MATCH childP<-[:VOTED_FOR]-(v:Vote)-[:VOTED_ON]->(c)
WHERE id(c) IN {characteristicIds}
WITH childP, c, avg(v.weight) as weight
RETURN childP AS product, sum(weight) as weight
ORDER BY weight DESC

不过，我想确保我理解您的要求。这个查询是否表现不佳？您是否试图防止它在未来表现不佳？

Answer 2

如果我们谈论性能问题，附加分析信息会很有用：http://neo4j.com/docs/stable/how-do-i-profile-a-query.html

然后将更容易决定在哪里采取行动。

Answer 3

你也可以试试：

MATCH (c:Characteristic) WHERE id(c) IN {characteristicIds} 
WITH collect(c) as characteristics

MATCH (parentP:Product)-[:CONTAINS]->(childP:Product)
WHERE id(parentP) = {productId}
OPTIONAL MATCH childP<-[:VOTED_FOR]-(v:Vote)
WITH childP, v, head(filter(c in characteristics WHERE (v)-[:VOTED_ON]->(c))) as c
WHERE c is not null
WITH childP, c, avg(v.weight) as weight
RETURN childP AS product, sum(weight) as weight
ORDER BY weight DESC

由于对产品的投票比对每个特征的投票要少得多，因此我们从这些开始，然后检查特征。没有分贝很难说。