如何在 f# 中使这些简单的函数尾递归

Question

我有这两个功能

//Remove all even indexed elements from a list and return the rest
let rec removeEven l =
match l with
| x0::x1::xs -> x1::removeEven (xs)
| [] -> []
| [_] -> []

//combine list members into pairs
let rec combinePair l =
match l with
| x0::x1::xs -> (x0,x1) :: combinePair(xs)
| [] -> []
| [_] -> []

那工作。

但我现在想，我还不如学习一点关于尾递归的知识，我很难掌握它。

这就是为什么我认为如果我可以得到一些帮助来制作我自己的尾递归函数，也许它会变得更清楚它是如何工作的，而不是阅读我可能不理解的地方的示例以及我自己的代码（请记住，我是一个完整的 f# 新手 :)）

当然欢迎任何其他关于我的代码的建设性 cmets！

Answer 1

在 F# 中使函数尾递归的一种典型方法是使用列表（在本例中为 acc）来累积结果并反转它以获得正确的顺序：

let removeEven l =
    let rec loop xs acc =
        match xs with        
        | [] | [_] -> acc
        | _::x1::xs' -> loop xs' (x1::acc)
    loop l [] |> List.rev

let combinePair l =
    let rec loop xs acc =
        match xs with        
        | [] | [_] -> acc
        | x0::x1::xs' -> loop xs' ((x0, x1)::acc)
    loop l [] |> List.rev

由于我们只是在每次递归调用 loop 后返回结果，因此这些函数是尾递归的。

你的函数看起来很不错，但我还有几个 cmets：

• 缩进在 F# 中很重要。我更喜欢 match... with 在 lec rec 声明后面几个空格。
• 模式匹配案例应遵循一致的顺序。最好先从基本案例开始。
• 只要有fun t -> match t with 的模式，function 关键字自然会用于缩短函数。
• 最好去掉不必要的括号，尤其是在具有一个参数的函数中。

应用上面的cmets，你的函数变成如下：

// Remove all even indexed elements from a list and return the rest
let rec removeEven = function
    | [] | [_] -> []
    | _::x1::xs -> x1::removeEven xs

// Combine list members into pairs
let rec combinePair = function
    | [] | [_] -> []
    | x0::x1::xs -> (x0, x1)::combinePair xs

Answer 2

如果您需要使用更多内存的速度较慢、可维护性较差的方式来执行此操作，则可以使用延续。

let removeEven items = 
  let rec loop f = function
    | _::h::t -> loop (fun acc -> f (h::acc)) t
    | [] | [_] -> f []
  loop id items

但是，嘿，它是尾递归的。