解构受歧视的工会

Question

我有一个有区别的联合类型的表单

type ParameterName = string
type ParameterValues =
    | String of string[]
    | Float of float[]
    | Int of int[]
type Parameter = Parameter of ParameterName * ParameterValues

我想将 ParameterValues 部分传递给采用通用参数返回单元的函数，例如

let func1 (name:string) (data:'a) = printfn "%s" name

要解构Parameter，我可以像这样包装func1

let func2 (Parameter (name, values)) =
    match values with
        | String s -> func1 name s
        | Float s -> func1 name s
        | Int s -> func1 name s

但是，如果我必须为多个功能执行此操作，这很不方便。相反，我想定义一个更灵活的包装器，如下所示：

let func3 (fn: ('a -> 'b -> unit)) (Parameter (name, values)) =
    match values with
        | String s -> fn name s
        | Float s -> fn name s
        | Int s -> fn name s

但是这失败了，因为b 的类型在匹配表达式的第一个选项中被限制为string[]；因此匹配表达式失败并出现错误Type string does not match type float.

这是预期的吗？我该如何解决这个问题？

Answer 1

这是预期的行为。问题是您不能直接将泛型函数作为参数传递给 F# 中的另一个函数。当你如下定义一个函数时：

let func3 (fn: ('a -> 'b -> unit)) (Parameter (name, values)) = (...)

...您正在定义一个泛型函数func3，它有两个泛型参数，并且当它们被指定时，可以使用给定的函数和一个参数来调用。这可以写成：

\forall 'a, 'b . (('a -> 'b -> unit) -> Parameter -> unit)

您需要做的是使这些类型参数不是顶级的，而是使第一个参数本身成为泛型函数。你可以这样写：

(\forall 'a, 'b . ('a -> 'b -> unit)) -> Parameter -> unit

这可以使用接口在 F# 中笨拙地编写：

type IFunction<'a> =
  abstract Invoke<'b> : 'a -> 'b -> unit

let func1 = 
  { new IFunction<string> with
    member x.Invoke<'b> name (data:'b) = printfn "%s" name }

let func3 (fn: IFunction<string>) (Parameter (name, values)) =
    match values with
    | String s -> fn.Invoke name s
    | Float s -> fn.Invoke name s
    | Int s -> fn.Invoke name s

实际上，您的函数实际上并不需要是通用的，因为您从不使用第二个参数 - 但您可以通过将数据传递为 obj 来实现使用此接口技巧可以实现的几乎任何东西你的代码会比这个怪物简单得多！

Answer 2

根据 Lee 和 Tomas 的建议，我想出了以下解决方案：

type Parameter = Parameter of string * obj

let func0 (name:string) (data:obj) = printfn "%s %A" name data

let func1 (fn: string->obj->unit) (Parameter (name, value)) =
    fn name value

let p1 = Parameter ("p1", [|"a"; "b"|])
let p2 = Parameter ("p1", [|1.; 2.|])

func1 func0 p1
func1 func0 p2