addChild 自定义类 AS3

Question

这是我尝试将其实例化到我的主类中的类：

public class Character extends Sprite {

    [Embed(source='../lib/front1.svg')]
    private var front1Class:Class;
    private var crosshair:Sprite = new front1Class ();

    public function Character() {
        trace("started");
        Mouse.hide();

        crosshair.scaleX = 5;
        crosshair.scaleY = 5;
        this.addChild(crosshair);

        stage.addEventListener(Event.ENTER_FRAME, MrEveryFrame);
        stage.addEventListener(MouseEvent.CLICK, click);
    }


    private function click(evt:MouseEvent):void {
        trace("clicked @ " + evt.stageX + "," + evt.stageY);

    }
    public function MrEveryFrame(e:Event):void
    {
        crosshair.x = mouseX - 15;
        crosshair.y = mouseY - 15;


    }

}

当我将它设置为文档类时，它工作正常。

但是...当我将 THIS 作为我的文档类并尝试从那里调用它时：

public class Shell extends Sprite
{


    private var character:Sprite = new Character ();


    public function Shell() 
    {

        addChild(character);


    }


}

它中断了，不再显示精灵对象（尽管它确实擦除了鼠标指针）。

这里有什么问题？您不能将自定义精灵或影片剪辑类实例化为 DisplayObject 类？？？

Answer 1

阶段是构造函数中的null。正如您自己发现的那样，这仅在您的类是文档类时才有效。所以像这样改变你的构造函数：

public function Character() {
    trace("started");
    Mouse.hide();

    crosshair.scaleX = 5;
    crosshair.scaleY = 5;
    this.addChild(crosshair);

    addEventListener(Event.ADDED_TO_STAGE, onAddedToStage);
}

private function onAddedToStage(event:Event):void
{

    stage.addEventListener(Event.ENTER_FRAME, MrEveryFrame);
    stage.addEventListener(MouseEvent.CLICK, click);
}

添加监听器会在stage已知后才访问stage，不再是null