ActionScript 3 - 向对象添加渐变

Question

我有一个名为“BlueBox”的影片剪辑实例，它只是一个蓝色的“绘图对象”。它在一个名为“option1MC”的容器内，该容器位于舞台上的“option1Container”内。它的颜色可以像这样更改：

option1Container.addEventListener(MouseEvent.MOUSE_OVER, option1ContainerOver);

var optionOver:ColorTransform = new ColorTransform();
optionOver.color = 0xC56516;

function option1ContainerOver(evt:Event):void {
    option1Container.option1MC.BlueBox.transform.colorTransform = optionOver;
}

我想将颜色更改为渐变。这是我尝试过的：

var mtr:Matrix = new Matrix();
mtr.createGradientBox(option1Container.option1MC.BlueBox.width, option1Container.option1MC.BlueBox.height, 0, 0, 0);
mtr.graphics.beginGradientFill(GradientType.LINEAR, [0xFF0000, 0x0000FF], [1, 1], [0x00, 0xFF], mtr); 
mtr.graphics.drawRect(0,0,option1Container.option1MC.BlueBox.width, option1Container.option1MC.BlueBox.height);

但是，现在当我运行 .fla 文件时，我给我一个错误提示：

Access of possible undefined property graphics through a reference with static type flasg.geom:Matrix:

指的是行

mtr.graphics.beginGradientFill(GradientType.LINEAR, [0xFF0000, 0x0000FF], [1, 1], [0x00, 0xFF], mtr); 
mtr.graphics.drawRect(0,0,option1Container.option1MC.BlueBox.width, option1Container.option1MC.BlueBox.height);

知道为什么吗？

Answer 1

Matrix 没有 graphics 属性。您需要将此应用于具有graphics 属性的DisplayObject。使用您的设置看起来像这样：

//create the sprite to do the gradient fill on or use your MovieClip
//var spriteObject:Sprite = new Sprite() or just use option1Container;

//enter your matrix
var mtr:Matrix = new Matrix(); 
mtr.createGradientBox(option1Container.BlueBox.width, option1Container.BlueBox.height, 0, 0, 0);

//apply it to the sprite
sprite.graphics.beginGradientFill("linear", [0xFF0000, 0x0000FF], [1, 1], [0x00, 0xFF], mtr); 
sprite.graphics.drawRect(0, 0, 50, 40); 
sprite.graphics.endFill(); 
addChild(sprite);

我在这里创建了一个精灵变量，这不是必需的，因为您可以将sprite 与option1Container 交换

您也可以参考 adobe 的帮助：http://help.adobe.com/en_US/as3/dev/WS5b3ccc516d4fbf351e63e3d118a9b90204-7dd7.html

现在，如果您在 IDE 中绘制 MovieClip 图形，您目前将无法更改它。在这种情况下，您可以创建一个新的 MovieClip 并将其添加到您的容器中，如下所示：

//note I made a target variable just to save on typing:
var target:MovieClip = option1Container.option1MC.BlueBox;
var gradientLayer:MovieClip = new MovieClip();

var gradientBox:Matrix = new Matrix(); 
gradientBox.createGradientBox(target.width, target.height, 0, 0, 0); 
gradientLayer.graphics.beginGradientFill("linear", [0xFF0000, 0x0000FF], [1, 1], [0x00, 0xFF], gradientBox); 
gradientLayer.graphics.drawRect(0, 0, target.width, target.height); 
gradientLayer.graphics.endFill(); 

//giving the asset a name will allow you to easily remove it later
gradientLayer.name = "gradientLayer";

target.addChild(gradientLayer);

请注意，我将渐变资源命名为“gradientLayer”。如果你想稍后删除这个孩子，你可以这样做：

option1Container.option1MC.BlueBox.removeChild( option1Container.option1MC.BlueBox.getChildByName( "gradientLayer" ) );