Flash/AS3 可以不考虑 Content-Type 加载外部图像吗？

Question

免责声明：我不是 Flash 开发人员 但我正在尝试解决闪存问题。 请不要以为我很亲密 熟悉 AS 或 Flash，因为我是 不是。

我目前的困境是我托管的资源是application/octet-stream。在我的 Actionscript 代码中，我使用了一些库（据我所知）执行 new Image 并将资源加载到创建的对象中。

有一个方法，loadImage(url)，它接受一个 url，你可以在其中向它提供图像的路径。

我无权访问loadImage 源代码，所以我不知道它究竟做了什么，但是工作的那个可以很好地加载图像，因为Content-Type 是image/jpeg。不工作的一个（我正在尝试修复的这个）不是因为 Content-Type 不同。

我想知道是否有人可以告诉我是否可以让 flash 基本上解析 URI，就好像它是 image/jpeg，而不管 Content-Type 是什么？

我无权访问源 目前的代码，但我只是 把它扔在那里以获得输入

如果需要，我明天会尝试获取一些源代码

编辑：好的，我现在可以访问源代码了。这是加载图像的部分：

postcardImage = new Image();
postcardImage.loadImage(imagePath);

我假设 Image 构造函数是 flash/AS 的原生构造函数，但我无法通过 google 搜索 loadImage 方法，所以它必须是自定义的，对吧？

或者 Image 构造函数本身可以是自定义的吗？原始Image 的扩展版本，带有loadImage 方法等？

不管怎样，有谁知道如何查看loadImage的源代码？

编辑#2：我做了一个ack-grep 并找到了库中定义的loadImage 方法的源代码：

public class Image extends Sprite {

    private var _source:String;
    private var _loader:Loader;
    private var _bmapData:BitmapData;
    private var _loadedBytes:Number;
    private var _totalBytes:Number;

    public function Image() {
        trace('IMAGE');
    }

    public function loadImage(s:String):void {
        _source = s;
        _loader = new Loader();
        _loader.contentLoaderInfo.addEventListener(Event.COMPLETE, onLoaded);
        _loader.contentLoaderInfo.addEventListener(Event.INIT, onLoading);
        _loader.contentLoaderInfo.addEventListener(ProgressEvent.PROGRESS, onProgress);
        _loader.load(new URLRequest(_source));

        function onProgress(e:ProgressEvent):void {
            _loadedBytes = e.target.bytesLoaded;
            dispatchEvent(new ProgressEvent(ProgressEvent.PROGRESS));
            if(!_totalBytes) {
                setTotalBytes(e.target.bytesTotal);
            }
        }

        function onLoading(e:Event):void {
            _loader.contentLoaderInfo.removeEventListener(Event.INIT, onLoading);
        }

        function onLoaded(e:Event):void {
            _bmapData = e.target.content.bitmapData;
            addChild(e.target.content);
            dispatchEvent(new Event(Event.COMPLETE));
            _loader.contentLoaderInfo.removeEventListener(Event.COMPLETE, onLoaded);
        }
    }

    public function getBmapData():BitmapData {
        return _bmapData;
    }

    public function duplicate():Image {
        var dup:Image = new Image();
        dup.addChild(new Bitmap(_bmapData.clone()));
        return dup;
    }

    public function getLoadedBytes():Number {
        return _loadedBytes;
    }

    private function setTotalBytes(n:Number):void {
        _totalBytes = n;
        dispatchEvent(new Event("TOTALBYTES_SET"));
    }

    public function getTotalBytes():Number {
        return _totalBytes;
    }

}   

任何人都可以就我如何在这方面做loadBytes 提供建议吗？我正在考虑定义一个自定义方法，loadResource 或无论 Content-Type 如何都可以加载的东西......或者只是在当前 load 方法和内部创建一个可选参数，根据传递的内容进行分支。

Answer 1

我最近一直在使用 ByteArray 方法，这听起来很有趣。我已经使用传递八位字节流的 URL 的方法修改了您的 Image 类。让我知道它是如何工作的！

注意：我没有设置 _loadedBytes 和 _totalBytes 属性，而是绘制加载的图像以启用公共 'getBmapData' 方法。

package {
import flash.utils.ByteArray;
import flash.net.URLStream;
import flash.display.Bitmap;
import flash.net.URLRequest;
import flash.events.ProgressEvent;
import flash.events.Event;
import flash.display.BitmapData;
import flash.display.Loader;
import flash.display.Sprite;

public class Image extends Sprite {

    private var _source : String;
    private var _loader : Loader;
    private var _bmapData : BitmapData;
    private var _loadedBytes : Number;
    private var _totalBytes : Number;
    private var _stream : URLStream;
    private var _bytes:ByteArray;

    public function Image() {
        trace('IMAGE');
    }

    public function loadImage(s : String) : void {
        _source = s;
        _loader = new Loader();
        _loader.contentLoaderInfo.addEventListener(Event.COMPLETE, onLoaded);
        _loader.contentLoaderInfo.addEventListener(Event.INIT, onLoading);
        _loader.contentLoaderInfo.addEventListener(ProgressEvent.PROGRESS, onProgress);
        _loader.load(new URLRequest(_source));

        function onProgress(e : ProgressEvent) : void {
            _loadedBytes = e.target.bytesLoaded;
            dispatchEvent(new ProgressEvent(ProgressEvent.PROGRESS));
            if(!_totalBytes) {
                setTotalBytes(e.target.bytesTotal);
            }
        }

        function onLoading(e : Event) : void {
            _loader.contentLoaderInfo.removeEventListener(Event.INIT, onLoading);
        }

        function onLoaded(e : Event) : void {
            _bmapData = e.target.content.bitmapData;
            addChild(e.target.content);
            dispatchEvent(new Event(Event.COMPLETE));
            _loader.contentLoaderInfo.removeEventListener(Event.COMPLETE, onLoaded);
        }
    }



    // ByteArray methods
    // adapted from Ted Patrick's 
    // http://ted.onflash.org/2007/12/progressive-image-loading-with.php

    public function loadBytes( s:String = "" ):void {

        // FOR EASY TESTING ONLY:
        if( s == "" ) s = "http://onflex.org/flexapps/applications/ProgressiveImageLoading/jpg.jpg";        

        // create URLStream with listeners
        _stream = new URLStream();
        _stream.addEventListener( ProgressEvent.PROGRESS , streamProgress );

        // Not firing, so lets not use it...
        //_stream.addEventListener( Event.COMPLETE , streamComplete );


        // create Loader for later
        _loader = new Loader();

        // create new ByteArray instance
        _bytes = new ByteArray();

        // go ahead and add it to the display list
        addChild( _loader );

        // start the show!
        _stream.load( new URLRequest(s) );

    }

    private function streamProgress(p : ProgressEvent) : void {

        trace("PROGRESS: ",  p.bytesLoaded, "of", p.bytesTotal );

        if( _stream.connected ) _stream.readBytes(_bytes, _bytes.length );

        if( _bytes.length == p.bytesTotal ) {

            // get rid of the event listeners to avoid re-firing 
            _stream.removeEventListener( ProgressEvent.PROGRESS , streamProgress ); 

            streamComplete();   
        }
    }

    private function streamComplete() : void {
        _loader.loadBytes( _bytes );
        _loader.contentLoaderInfo.addEventListener( Event.INIT, makeBitmapData );
    }

    private function makeBitmapData( e:Event ):void{

        _loader.contentLoaderInfo.removeEventListener( Event.INIT, makeBitmapData );

        // set the bitmapData for the other public methods
        _bmapData = new BitmapData(_loader.width, _loader.height );
        _bmapData.draw( this );
    }

    //-----




    public function getBmapData() : BitmapData {
        return _bmapData;
    }

    public function duplicate() : Image {
        var dup : Image = new Image();
        dup.addChild(new Bitmap(_bmapData.clone()));
        return dup;
    }

    public function getLoadedBytes() : Number {
        return _loadedBytes;
    }

    private function setTotalBytes(n : Number) : void {
        _totalBytes = n;
        dispatchEvent(new Event("TOTALBYTES_SET"));
    }

    public function getTotalBytes() : Number {
        return _totalBytes;
    }
}  
} 

Answer 2

简短回答：是的。

我假设代码在幕后使用Loader 对象来执行实际的图像加载/检索（这是执行此类操作的标准方式）。加载器对象支持 PNG、JPEG 和 GIF（仅限第一帧）格式。

现在，我不确定加载器是否使用响应的内容类型来猜测图像格式（我猜不是，但我可能是错的）。我知道 Loaders 有一个 loadBytes() 方法，它直接从原始字节加载图像——在这种情况下，嗅探 only 的格式使用图像的实际数据，因为没有直接涉及 HTTP 请求.因此，如果罪魁祸首确实是内容类型，您可以将图像作为原始数据单独加载，然后使用 loadBytes() 从该原始数据中获取图像对象，从而完全绕过该问题。

当然，我们必须查看代码才能真正了解发生了什么。