actionscript - 同步 2 个声道？

Question

我正在使用 2 个声道同时播放 2 个单独的、外部加载的 mp3 文件。现在我将播放按钮绑定到启动第一个 mp3 的功能，然后是第二个。问题是 - 第二个 mp3 在第一个之后几毫秒开始。有没有办法可以确保这两个同时开始播放？

function playMusic(evt:MouseEvent):void
{

    channel = myMusic.play(songPosition);
    channel2 = myMusic2.play(songPosition);
    myTimer.start();
    btnPlay.mouseEnabled = false;
}

编辑：我发现了一个与 2 个音频源的 TIMER 匹配的笨拙解决方法。它有效，但现在我在尝试匹配时开始打嗝：

    function updateTime(evt:TimerEvent):void
    {
        lblSongTime.text = convertTime(channel.position);
        if(channel.position!=channel2.position){   
 trace("out of sync")                
 SoundMixer.stopAll()
    channel = myMusic.play();
    channel2 = myMusic2.play(channel.position);

        }
    }

Answer 1

如果您的目标是 Flash Player 10+，那么您可以使用声音类的 sampleData event 和 extract method 来组合这两种声音。

基本上，您需要创建一个处理sampleData 事件的Sound 子类，方法是将位置传递给您要播放的两种声音中的每一种的extract 方法。然后，您将合并这两个 ByteArrays 并将其插入到事件的 data 成员中。

需要注意的主要事情是，您一次最多只能向sampleData 事件提供 8k 数据（如果我没记错的话）。您可能还希望平均两种声音，或者至少在组合声音时降低音量。

我已经有一段时间没有写动作脚本了，所以我需要一些时间来为你写一些代码，但如果你仍然需要帮助，请告诉我，我会尽力给你更多信息或一些代码。

编辑

这是一个最小的类，可以做你想做的事。您应该添加错误检查，并且您可能需要添加东西来处理声音转换（例如音量调整），因为使用示例数据事件可能会忽略您在播放时应用的声音转换（我不记得了，但它不应该太你很难弄清楚^_^​​)...

import flash.events.SampleDataEvent;
import flash.media.Sound;
import flash.utils.ByteArray;

public class DualSound extends Sound {
    private var sa:Sound;
    private var sb:Sound;

    public function DualSound(a:Sound, b:Sound) {
        super();

        sa = a;
        sb = b;

        addEventListener(SampleDataEvent.SAMPLE_DATA, handleSampleData);
    }

    private function handleSampleData(e:SampleDataEvent):void {
        var ba:ByteArray, bb:ByteArray;

        ba = new ByteArray();
        bb = new ByteArray();

        sa.extract(ba, 8 << 10, e.position);
        sb.extract(bb, 8 << 10, e.position);
        ba.position = 0;
        bb.position = 0;

        while(ba.bytesAvailable > 0 && bb.bytesAvailable > 0) {
            e.data.writeFloat((ba.readFloat() + bb.readFloat()) / 2);
        }
        if(ba.bytesAvailable > 0) {
            e.data.writeBytes(ba, ba.position, ba.bytesAvailable);
        } else if(bb.bytesAvailable > 0) {
            e.data.writeBytes(bb, bb.position, bb.bytesAvailable);
        }
    }
}