在 ActionScript 3 中扩展对象原型

Question

每当我尝试扩展 Object 原型时，都会出现错误：

错误 #1056：无法在 mx.core.UIComponentDescriptor 上创建属性 my_extension。

我四处寻找，发现了这些：

Flash AS3: ReferenceError: Error #1056: Cannot create property

ReferenceError: Error #1056 - instance name Error

我没有使用可视化 IDE 来设计舞台，而是使用 MXML 和 AS3 文件，所以我不确定如何解决这个错误。

我的代码：

Object.prototype.keys = function(): Array {
  var keys: Array = [];

  for (var key: * in this) {
    keys.push(key);
  }

  return keys;
}

Object.prototype.values = function(): Array {
  var values: Array = [];

  for each (var value: * in this) {
    values.push(value);
  }

  return values;
}

Answer 1

使用prototype 扩展一个类看起来很像ActionScript 1 或2。

在 AS3 中，如果类是动态的，您也许可以进行原型设计。

原型有缺点：

• 只能扩展动态类，例如不能向 Math 添加方法。
• 对存储在原型中的方法的调用需要更长的时间来执行。
• 由于方法是在运行时添加的，因此编辑器无法通过代码提示或使用正确的语法高亮显示它们。

由于所有类都扩展了对象，因此无需显式声明Object 作为基类；但是，您可以定义要扩展的 AbstractObject 类：

package
{

    public dynamic class AbstractObject extends Object
    {

        public function AbstractObject()
        {
            super();
        }

        public function get keys():Array
        {
            var keys:Array = [];

            for (var key:* in this)
            {
                keys.push(key);
            }

            return keys;
        }

        public function get values():Array
        {
            var values:Array = [];

            for each (var value:* in this)
            {
                values.push(value);
            }

            return values;
        }

    }
}

您的课程的子类型 AbstractObject。