通过合成创建影片剪辑时多次使用实例

Question

进一步编辑：添加了第二个参数，以阐明 TreeGenerator 使用的是通过参数传递的 Sprite 中预先创建的部分，而不是生成它们。

编辑：我试图将代码更改为不再使用“形状”和“MovieClips”，因为这有点令人困惑和模糊我遇到的问题。

我正在尝试使用其他 Sprite 的那部分来创建 Sprite。我发布了一些代码来说明我正在尝试做的事情：

public class TreeGenerator extends Sprite 
{
    private var _leaf:Sprite
    private var _branch:Sprite
    private var _trunk:Sprite
    //these are separately drawn and instantiated in other sprites,
    //one of which will be passed through in the parameters

    public var thumbnail:Sprite

    public function TreeGenerator($preCreatedTreeOne:Sprite, $preCreatedTreeTwo:Sprite) 
    {
        _leaf = $preCreatedTreeOne.leaf;
        _branch = $preCreatedTreeTwo.branch;
        _trunk = $preCreatedTreeOne.trunk;

        thumbnail = $preCreatedTreeOne.leaf;
        //just uses the leaf for this example

        this.addchild(_leaf);
        _leaf.y = 30;
        this.addchild(_branch);
        _branch.y = 20;
        this.addchild(_trunk);
        _trunk.y = 10;
        //this "puts together" the tree image (though very
        //simply with just y for example purposes)

        this.addchild(thumbnail);
        thumbnail.y = 40;
        //this thumbnail is supposed to be a separate object that can also
        //be interacted with but this example neglects the event listeners.
        //the important thing here is the setting of the y to 40, which 
        //overwrites the y of 30 for _leaf.
    }
}

我正在通过已经实例化为 $preCreatedTreeOne 和 $preCreatedTreeTwo 的两个 Sprite，它们是通过各种可供选择的树部分（大绿叶、小红叶、细枝、粗枝等）创建的。这些精灵是绘制的图像，而不是在代码中生成的图像（比如来自 .swc 库）。当用户在舞台上单击两棵树后单击按钮时，TreeGenerator 将创建另一棵树的图像，包括叶子、树枝和树干，但这次使用的是两棵预先创建的树的部分（它将是动态，单击将生成一棵树，一棵树有绿叶，二棵树有粗树枝，一棵树有一根细树干，选择两棵树的组合为“一”或“二”）。还有一个单独的缩略图可以独立交互（尽管在示例中省略了该代码）。

但是，当我运行代码时，我看到 _leaf 的 y 坐标值被缩略图覆盖，因为我现在意识到两者现在都是 $preCreatedTreeOne.leaf。

如何从 $preCreatedTreeOne 中“获取”额外的 $preCreatedTreeOne.leaf 实例（或副本），以便在将它们存储在不同变量中时可以独立操作它们？

Answer 1

IGraphicsData

您可以创建对应于对绘图 API 方法的调用的对象。它们都实现了上述接口。然后，您可以将它们分组到 Vector.<IGraphicsData> 中并将它们推入 drawGraphicsData() 以将您的东西绘制在 Graphics 对象中。

你不是在传递食物，而是传递它的食谱。然后，您可以根据食谱烹制任意数量的饭菜。

从 FP 11.6 开始，您还可以通过 readGraphicsData() 从 Graphics 对象查询 Vector.<IGraphicsData>

免责声明：我在 wonder.fl 中修改了您的示例代码的修改版本，因为我没有安装编译器，请使用单独的类文件而不是内部类正确实现它。

我的 Flash Player 来自那个年代，当时它还很酷，因此有点旧 (11.2)，这意味着我实际上无法使用 readGraphicsData() 测试代码，这就是我通过所有 3 个参数的三角形列表。

package 
{
    import flash.display.Shape;
    import flash.display.Sprite;
    import flash.display.IGraphicsData;
    import flash.display.GraphicsPath;
    import flash.display.GraphicsSolidFill;
    
    import flash.display.GraphicsEndFill;
    
    public class Main extends Sprite 
    {
        public function Main() 
        {
            
            // assemble Vector.<IGraphicsData> manually for triangle
            var triangle:GraphicsPath = new GraphicsPath();
            var triangleHeight:uint = 30; 
            triangle.moveTo(triangleHeight / 2, 0); 
            triangle.lineTo(triangleHeight, triangleHeight); 
            triangle.lineTo(0, triangleHeight); 
            triangle.lineTo(triangleHeight / 2, 0);
            
            var commands:Vector.<IGraphicsData> = new <IGraphicsData>[new GraphicsSolidFill(0xff0000), triangle, new GraphicsEndFill()];

            addChild(new ShapeSet(commands, commands, commands));
            
            // since FP 11.6 the following is also possible
            
            // assemble Vector.<IGraphicsData> from existing Graphics object in Shape
            var square:Shape = new Shape();
            square.graphics.beginFill(0xff00);
            square.graphics.drawRect(0, 0, 30, 30);
            square.graphics.endFill();
            
             addChild(new ShapeSet(square.graphics.readGraphicsData(), commands, commands));
        }
    }
}
import flash.display.Sprite;
import flash.display.Shape;
import flash.display.IGraphicsData;

internal class ShapeSet extends Sprite
{
    private var _square:Shape;
    private var _triangle:Shape;    
    private var _thumbnail:Shape;

    public function ShapeSet(square:Vector.<IGraphicsData>, triangle:Vector.<IGraphicsData>,  thumbnail:Vector.<IGraphicsData>) 
    {
        _square = new Shape();
        _triangle = new Shape();
        _thumbnail = new Shape();

        addChild(_square);
        _square.x = 10;
        addChild(_triangle);
        _triangle.x = 60;
        addChild(_thumbnail);
        _thumbnail.x = 90;
        
        _square.graphics.drawGraphicsData(square);
        _triangle.graphics.drawGraphicsData(triangle);
        _thumbnail.graphics.drawGraphicsData(thumbnail);
    }
}

如果你只想将三角形​​传递给三角形，你应该编写一个三角形类，封装Vector.<IGraphicsData>，并确保它只包含表示三角形的数据。如何做到这一点超出了这个问题的范围。