Action Script 中作为事件处理程序的匿名函数 - 好还是坏？

Question

我从 JS 世界来到 AS3，我应该承认匿名函数是我的弱点。我倾向于在任何地方使用它们。现在，来到 AS3，我在很多地方听到和读到，AS 和 Flash 在处理垃圾收集方面非常糟糕，应该手动清空、处理和删除所有事件处理程序和对象，以避免奇怪和无法解释的内存泄漏和崩溃。不确定这其中的哪一部分是正确的，但我想从一开始就遵循最佳做法。

所以我的问题是 - 使用匿名函数作为事件处理程序的想法有多糟糕？例如，考虑这样的代码：

addEventListener(Event.ENTER_FRAME, function() : void {
    controls.elapsed = stream.time;
});

contorls.elapsed 是设置器，除了设置视频播放器的当前播放时间外，还会更新整个 UI，stream 是 NetStream 对象，流式传输实际视频。

还有很多其他地方可以使用匿名函数使代码更简洁、更直观。检查以下代码以获得控制栏的简单淡入效果：

public function showControls() : void
    {
        var self:Controls = this;

        if (!visible) {
            visible = true;
            fadeTimer = new Timer(30, 10);
            fadeTimer.addEventListener(TimerEvent.TIMER, function() : void {
                self.alpha += 0.1;
            });
            fadeTimer.addEventListener(TimerEvent.TIMER_COMPLETE, function() : void {
                self.alpha = 1;
            });
            fadeTimer.start();
        }
    }

我非常喜欢它的外观并适合代码，但我担心泄漏。虽然 Event.ENTER_FRAME 处理程序可能永远不会以这种形式变得有害，但计时器侦听器呢。我应该手动删除这些侦听器，还是一旦我设置 fadeTimer = null 就会自动删除它们？是否可以完全删除带有匿名函数的侦听器？

Answer 1

刚刚注意到这篇文章 - 有几件事可能对您有用。一个是 arguments.callee（它是对您所在的当前函数的引用）。这对于删除匿名函数中的引用很有用。此外，您可以在 addEventListener 代码中使用弱引用——但是，这不适用于匿名变量，因为它们几乎会立即被 GC。为简单起见，我像这样重写了您的代码：（应该可以工作-尚未测试）

private function showControls() : void {

    if (visible) {
        return;
    }

    var self:DisplayObject = this;

    var fadeTimer= new Timer(30,10);
    var handler = function(e:Event) {

        switch (e.type) {

            // timer complete
            case TimerEvent.TIMER_COMPLETE:

                // remove references to this anonymous function -- for garbage collection
                fadeTimer.removeEventListener(TimerEvent.TIMER_COMPLETE, arguments.callee);
                fadeTimer.removeEventListener(TimerEvent.TIMER, arguments.callee);

                // break out
                return self.alpha = 1;

            // timer
            case TimerEvent.TIMER:
                return self.alpha += 0.1;

        }
    }

    fadeTimer.addEventListener(TimerEvent.TIMER, handler);
    fadeTimer.addEventListener(TimerEvent.TIMER_COMPLETE, handler);
    fadeTimer.start();

}

Answer 2

我会这样做。而且，当您想确保在中断时清除计时器时，请务必使用 dispose()。

private function showControls() : void
{
    if(_isVisible)
        return;

    // start you control here
    _fadeTimer = new Timer(30, 10);
    _fadeTimer.removeEventListener(TimerEvent.TIMER, updateFade);
    _fadeTimer.removeEventListener(TimerEvent.TIMER_COMPLETE, updateFadeComplete);
    _fadeTimer.start();
}

private function updateFade(event : TimerEvent) : void
{
    // update fade here
}

private function updateFadeComplete(event : TimerEvent) : void
{
    dispose();
}


private function dispose() : void
{
    if(_fadeTimer)
    {
        _fadeTimer.stop();
        _fadeTimer.removeEventListener(TimerEvent.TIMER, updateFade);
        _fadeTimer.removeEventListener(TimerEvent.TIMER_COMPLETE, updateFadeComplete);
        _fadeTimer = null;
    }
}

Answer 3

在可行的地方使用函数方法并没有错。就内存泄漏而言，您需要将对象跟踪到舞台以查看是否可以将其删除。

向控件添加ENTER_FRAME 事件处理程序可确保控件 具有对匿名函数 的引用。由于代码是控件的一部分（或者看起来如此），这很好，因为当控件存在时，匿名函数将被删除。

向计时器添加事件处理程序可确保计时器 具有对匿名函数 的引用。如果计时器正在运行，它将使匿名函数引用保持活动状态，并通过关联保持实体控件。但是，一旦计时器停止，它和函数都应该被收集。

如果一切都失败了，请使用分析器看看！ ;)