使用嵌套循环将文件列表中的文件复制到文件夹列表中的文件夹，批量

Question

我想同时读取文件列表和文件夹列表，并将每个文件复制到每个文件夹中，并重命名文件。

以下是我的原始代码。外部循环不会增加。我已经尝试了所有方法来应用我读过的关于循环和延迟扩展的内容，但没有任何效果。

谁能告诉我如何修复代码或改用什么代码？

编辑以澄清问题：每次迭代时，“echo src”都会回显 Filelist.txt 中的第一行。永不改变。另一方面，“echo dest”确实按预期（期望）通过 folderlist.txt。

@echo off
setlocal enabledelayedexpansion
:: var is set in calling routine
SET "newname=%var%_filename_0.jpg"   
    FOR /F  %%G IN (Filelist.txt) DO (
    FOR /F %%H IN (Folderlist.txt) DO (
        SET src=%%G
        SET dest=%%H
            echo src is !src!
            echo dest is !dest!
            REM Here with each iteration do a copy and rename
            :: copy "!src!" "!dest!\%newname%"  1>nul
  )
)

Answer 1

代码中的主要问题不是语法，而是概念。您的代码从文件列表中读取一行，然后对于这一行，读取文件夹列表中的所有行。

如果您嵌套了for 循环，则对于外部for 的每次迭代，都会执行内部循环的所有迭代。

如果您需要从两个文件中读取同步行，则需要类似

@echo off
    setlocal enableextensions disabledelayedexpansion

    < files (
        for /f "delims=" %%a in (folders) do (
            set /p "myFile="
            setlocal enabledelayedexpansion
            for /f "delims=" %%b in ("!myFile!") do (
                endlocal
                echo %%a %%b
            )
        )
    )

也就是说，使用for 命令读取文件夹列表，使用set /p 从标准输入读取文件列表。由于我们将文件列表重定向为输入，set /p 将从中获取其数据。