批处理文件将文件从文件夹内的特定子文件夹复制到目标文件夹

Question

我有一个和他一样的文件夹结构

folder1-------|
              |123456------123.txt
                          abc.txt
              |234567------fgt.txt
                           234.txt
              |abc---------ytr.txt
                           1234.txt

如果子文件夹的长度为 6(only numbers)，我需要从主文件夹子目录复制文件。所以 123456,234567 的 .txt 文件会被复制，abc 不会被复制。

我尝试过使用通配符，但还没有成功。提前致谢。

>xcopy /s "C:\Users\xxx.xxx\Desktop\folder1\*\*.txt" "C:\Users\xxx.xxx\Documents\New folder" /l /D:09-09-2019

Answer 1

好的，下面是一个例子：

@echo off
setlocal enabledelayedexpansion

for /f %%i in ('dir "C:\Users\xxx.xxx\Desktop\folder1\" /b /ad') do (
  set "str=#%%i"
  set "len=0"
  for %%a in (4096 2048 1024 512 256 128 64 32 16 8 4 2 1) do (
    if "!str:~%%a,1!" neq "" (
       set /a "len+=%%a"
       set "str=!str:~%%a!"
       if !len! equ 6 if 1%%i equ +1%%i echo %%i is !len! characters   
     )
   )
)

这将对您提供的路径内的目录执行dir。然后它会测试字符串的长度，如果长度是6个字符，它会测试字符串是否为数字，如果是，它会echo字符串（文件夹名称）和它的长度。然后你应该按原样测试它，如果它给你所需的输出，你可以用你的复制字符串替换 echo 部分。

所以你的最终解决方案是这样的：

@echo off
setlocal enabledelayedexpansion
set /p "mydate=Enter Date (format dd-mm-yyyy): "
for /f %%i in ('dir "C:\Users\xxx.xxx\Desktop\folder1\" /b /ad') do (
  set "str=#%%i"
  set "len=0"
  for %%a in (4096 2048 1024 512 256 128 64 32 16 8 4 2 1) do (
    if "!str:~%%a,1!" neq "" (
       set /a "len+=%%a"
       set "str=!str:~%%a!"
       if !len! equ 6 if 1%%i equ +1%%i xcopy "C:\Users\xxx.xxx\Desktop\folder1\%%i\*.txt" "C:\Users\xxx.xxx\Documents\New folder" /D:!mydate! 
     )
   )
)

Answer 2

您可以使用FindStr 来隔离与您的模式匹配的目录：

batch-file:

@Echo Off
Set "SrcDir=%UserProfile%\Desktop\folder1"
Set "DstDir=%UserProfile%\Desktop\New folder"
For /F Delims^=^ EOL^= %%A In ('
    "Dir /B/AD "%SrcDir%\*" 2>NUL|FindStr "^[0-9][0-9][0-9][0-9][0-9][0-9]$""
')Do XCopy "%SrcDir%\%%A\*.txt" "%DstDir%\" /D:09-09-2019 /Y>NUL 2>&1

只需修改 2 和 3 行上的 = 和 " 之间的路径，以适合您的实际源目录和目标目录。 p>

Answer 3

这是实现您想要的另一种方法（请参阅所有解释性rem 备注）：

@echo off
rem // Use a `for /D` loop to iterate through all immediate sub-directories in the given root directory:
for /D %%I in ("%UserProfile%\Desktop\folder1\*") do (
    rem // Store path and name of currently iterated directory in variables:
    set "DIRECTORY=%%~I" & set "NAME=%%~nxI"
    rem // Toggle delayed expansion to be able to write and to read a variable within the same block of code:
    setlocal EnableDelayedExpansion
    rem // Check if directory name holds more than 5 characters:
    if not "!NAME:~5!" == "" (
        rem // Check if directory name holds not more than 6 characters:
        if "!NAME:~0,6!" == "!NAME!" (
            rem // The directory name is exactly 6 characters long.
            rem // Check whether the directory name consists of decimal figures by (mis-)using a `for /F` loop:
            set "FLAG=" & for /F "tokens=1 delims=0123456789 eol=0" %%J in ("!NAME!") do set "FLAG=#"
            rem // The flag variable has not been set, hence the directory name consists of decimal figures:
            if not defined FLAG (
                rem // Do the actual copy job at this point:
                xcopy /I /Y /D:09-09-2019 "!DIRECTORY!\*.txt" "!UserProfile!\Documents\New Folder"
            )
        )
    )
    endlocal
)

您试图不仅在路径的最后一个元素中使用wildcards，这是无法做到的（在 Windows 中），但您可以使用 for /D loop 来解析上层目录中的通配符，如脚本。

脚本使用~-modifiers（对于for 元变量如%%I 和参数引用如%1 相同）来获取当前迭代目录的纯名称：%%~nxI。

要确定目录名称是否正好是六 (6) 个字符长，应用 sub-string expansion。

要确定目录名称是否仅包含十进制数字，for /F loop 被（错误）使用：for /F 在给定的分隔符处将字符串拆分为多个部分（选项delims）；由于所有十进制数字都被定义为分隔符，名为1a2b3c 的目录将被拆分为a、b 和c 部分（a 被分配给%%J，然后由于tokens=1，其他部分被忽略），但目录名称123456 没有留下任何东西，因为这是一个仅分隔符的字符串，在这种情况下for /F 循环根本不会迭代。连同在for /F 循环体中设置的类似标志的变量FLAG，我们能够确定循环是否迭代，从而知道当前目录名称是否仅包含十进制数字。

脚本在同一代码块中写入和读取变量NAME，这通常无法完成，除非您启用delayed variable expansion。

您可以使用system environment variable %UserProfile% 而不是指定C:\Users\xxx.xxx，因此该脚本甚至可以在用户配置文件目录不在默认位置的系统上运行。