WMIC 上的无效动词获取变量

Question

我正在尝试将主硬盘序列号获取到一个变量，以便稍后成为echoed。

我用过这个，效果很好：

for /f "tokens=2 delims== " %%k in ('WMIC path win32_physicalmedia get serialnumber /value') do (for /f "delims=" %%l in ("%%k") do set "SerialNumber=%%l")

但是，它只做最后一个序列号，我想得到主要的。

如果我使用这个命令，

"wmic path win32_physicalmedia where tag='\\\\.\\PHYSICALDRIVE0' get serialnumber /value" 

然后我只得到想要的序列号。

问题是当我尝试修改工作代码时，运行 bat 时出现错误：

动词无效。

努力上班：

for /f "tokens=2 delims== " %%k in ('wmic path win32_physicalmedia where tag='\\\\.\\PHYSICALDRIVE0' get serialnumber /value') do (for /f "delims=" %%l in ("%%k") do set SerialNumber=%%l)

错误：

无效动词

如果我只跑：

wmic path win32_physicalmedia where tag='\\\\.\\PHYSICALDRIVE0' get serialnumber /value in CMD

我得到以下输出：

SerialNumber=     WD-WCC2E1XJADRT

所以我知道该命令有效。

空格是否在中都没关系，我只想要=之后的内容。我在支持 WMIC 的 WINPE 中执行此操作，因此不能选择 Powershell。

总脚本

@echo OFF
setlocal
for %%v in (a b c d e f g h i j k l m n o p q r s t u v w x y z) do if exist %%v:\drives.txt set w=%%v

for /f "tokens=2 delims== " %%k in ('wmic path win32_physicalmedia where tag='\\\\.\\PHYSICALDRIVE0' get serialnumber /value)') do (for /f "delims=" %%l in ("%%k") do set SerialNumber=%%l)

for /F "tokens=2" %%i in ('date /t') do set "Date=%%i"
echo %SerialNumber%,%Date% >> %w%:\drives.txt

Answer 1

如果您将命令修改为：

WMIC Path Win32_PhysicalMedia Where "Tag='\\\\.\\PHYSICALDRIVE0'" Get SerialNumber /Value

= 将受到保护。

试试这样：

@Echo Off
For /F "Tokens=1*Delims==" %%A in ('
    WMIC Path Win32_PhysicalMedia Where "Tag='\\\\.\\PHYSICALDRIVE0'" Get SerialNumber /Value 2^>Nul
') Do For %%C In (%%B) Do Set "SerialNumber=%%C"
Echo [%SerialNumber%] & Pause

我添加最后一行只是为了显示任何返回的变量和值。

Answer 2

在 powershell 中会很容易。您可以在 winpe 的文件共享上提取 Powershell 6 (pwsh) 的 zip。 https://github.com/PowerShell/PowerShell/releases/download/v6.2.1/PowerShell-6.2.1-win-x64.zip

$SerialNumber = Get-CimInstance win32_physicalmedia | 
  Where tag -Match physicaldrive0 | Select -Expand serialnumber

这是另一种 .bat 方式（'%' 是 sql 通配符，您必须在 .bat 文件中将它们加倍）：

for /f "skip=1" %%i in ('wmic path win32_physicalmedia where "tag like '%%PHYSICALDRIVE0%%'" get serialnumber') do if not defined serialnumber set serialnumber=%%i