wmic 输出到文件而没有额外的行问题

Question

我查看了所有这些主题和帖子：

线程：https://superuser.com/questions/1082530/how-can-i-remove-the-last-blank-line-of-a-wmic-command

线程：How can I remove empty lines from wmic output?

线程：Parsing WMIC output

发帖：https://stackoverflow.com/a/37725658/8262102

到目前为止，没有任何帮助，他们中的大多数使用findstr /r /v "^$" 来执行此操作。

它们的问题在于，在我的情况下，输出在写入文件时包含额外的一行。

我想要的文件输出应该是：

[Microsoft Windows 10 Pro]

但我得到了：

[Microsoft Windows 10 Pro
]

这是我的代码，它将在您的桌面上创建输出文件：

@echo off
Setlocal EnableDelayedExpansion
cd /d "C:\Users\%username%\Desktop"
(
  for /f "skip=1 delims=" %%A in (
    'wmic OS get Caption ^| findstr /r /v "^$"'
    ) do echo [%%A]
  )>output.txt && exit

任何帮助将不胜感激。

Answer 1

最简单的解决办法是改变wmic的输出格式：

    For /F Tokens^=6Delims^=^" %%A In (
        '"%__AppDir__%wbem\WMIC.exe" OS Get Caption /Format:MOF'
    ) Do Echo [%%A]

上面的答案对所提出的问题有效，即从一个特定值返回字符串结果。根据您的附加信息，它不再有效，但这不是代码的错，而是您无法提出正确的问题。

对于您正在寻找的具体值，它们是 Manufacturer、Name、Description、CurrentClockSpeed、NumberOfCores 和 NumberOfLogicalProcessors，我会建议使用完全不同的方法，使用 @ 987654322@:

$c = GCIM "Win32_Processor"
$o = ForEach ($i in $c) {
    "Manufacturer:                 " + $i.Manufacturer
    "Name:                         " + $i.Name
    "Description:                  " + $i.Description
    "Current Clock Speed:          " + $([Math]::Round($i.CurrentClockSpeed/1000,2)) + " GHz"
    "Number Of Cores:              " + $i.NumberOfCores
    "Number Of Logical Processors: " + $i.NumberOfLogicalProcessors
}
$o | Out-File ".\CPUInfo.txt"

为了使用batch-file 标签保持主题，这是一个完整的batch-file，它利用powershell：

@"%__AppDir__%WindowsPowerShell\v1.0\powershell.exe" -NoP ^
  "$c = GCIM 'Win32_Processor';" ^
  "$o = ForEach ($i in $c) {" ^
    "\"Manufacturer:                 \" + $i.Manufacturer;" ^
    "\"Name:                         \" + $i.Name;" ^
    "\"Description:                  \" + $i.Description;" ^
    "\"Current Clock Speed:          \" + $([Math]::Round($i.CurrentClockSpeed/1000,2)) + \" GHz\";" ^
    "\"Number Of Cores:              \" + $i.NumberOfCores;" ^
    "\"Number Of Logical Processors: \" + $i.NumberOfLogicalProcessors};" ^
  "$o | Out-File \".\CPUInfo.txt\""

Answer 2

WMIC 的输出是 unicode ！

可以通过另一个 FOR /F 循环传递值来删除尾随 <CR>。

这也删除了幻象“空白”行（实际上是<CR>）

@echo off
for /f "skip=1 delims=" %%a in ('"wmic OS get Caption"') do (
    for /f "delims=" %%b in ("%%a") do set "MyVAR=%%~nb"
)
echo [%MyVAR%]
pause

Answer 3

我最终使用了@Hackoos 的解决方案，因为它允许获取诸如 wmic CPU get NumberOfCores 之类的值，但 Compos 的出色答案失败了，因为该值与它的值没有相同的分隔符，所以我已经修改用于可重用函数的 Hackoos 代码，如下所示：

@echo off
cd /d "C:\Users\%username%\Desktop"
set WMICGET_VALUE=
(

  call :WMICGET_ECHO CPU Manufacturer              "  Manufacturer:                  "
  call :WMICGET_ECHO CPU Name                      "  Name:                          "
  call :WMICGET_ECHO CPU Description               "  Description:                   "
  call :WMICGET_ECHO CPU CurrentClockSpeed         "">nul
  Setlocal EnableDelayedExpansion
  echo   Current Clock Speed:            !WMICGET_VALUE! Mhz / !WMICGET_VALUE:~0,1!.!WMICGET_VALUE:~1,2! GHz
  endlocal
  call :WMICGET_ECHO CPU NumberOfCores             "  Number Of Cores:               "
  call :WMICGET_ECHO CPU NumberOfLogicalProcessors "  Number Of Logical Processors:  "

  exit

rem Based on this answer: https://stackoverflow.com/a/63153964/8262102
:WMICGET_ECHO
for /f "skip=1 delims=" %%a in ('"wmic %1 get %2"') do (for /f "delims=" %%b in ("%%a") do echo %~3 %%~nb & set "WMICGET_VALUE=%%~nb")
goto :EOF
)>output.txt