遍历子文件夹的子文件夹并对最后一个子文件夹的每个文件执行命令

Question

考虑这个层次结构：

MainFolder\Sub_Folder1\Original_Files\
                      \Converted_Files\
          \Sub_Folder2\Original_Files\
                      \Converted_Files\

现在在每个...\Original_Files\ 中，我都有一堆视频文件，我将对其进行编码并保存到各自的...\Converted_Files\。

我可以使用此批处理代码为一个子文件夹执行此操作：

@echo off
set "sourcedir=G:\Animation\Anime\OnePiece\Episodes\Main"
set "outputdir=G:\Animation\Anime\OnePiece\Episodes\Converted"

PUSHD "%sourcedir%"

    for %%F in (*.mkv) DO ffmpeg -i "%%F" -s 640x480 -map 0 -c:v libx265 "%outputdir%\%%F"

POPD

我生成了一个包含所有子文件夹的文件夹路径的文本文件，其中包含：

G:\Animation\ToConvert\Berserk_1997_The_Complete_Series   
G:\Animation\ToConvert\Blue_Exorcist   
G:\Animation\ToConvert\Elfen_Lied

文件中列出的每个文件夹都包含Main 和Converted 文件夹。我必须遍历Main 中的所有文件并保存到Converted，如您在上面看到的那样。

这是我想出来的：

@echo off
for /F "tokens=*" %%A in (f.txt) DO (
    set "sourcedir=%A%\Main"
    set "outputdir=%A%\Converted"
    PUSHD "%sourcedir%"
       for %%F in (*.mkv) DO ffmpeg -i "%%F" -s 640x480 -map 0 -c:v libx265 "%outputdir%\%%F"
    POPD 
) %%A

运行 for /F "tokens=*" %A in (f.txt) DO @echo %A 会给我子文件夹的名称。

我想如果我可以将名称传递给某个变量并将\Main 和\Converted 连接到它，它可能会起作用。

但是在命令提示符窗口中运行上面的代码时，它只是将当前目录从我正在运行批处理文件的文件夹切换到C:\Windows。

如何运行嵌套循环，一个用于子文件夹，然后在Main 中工作和在Converted 中保存以及Main 中文件的下一个循环之间进行选择？

Answer 1

您的上一个批处理代码失败是因为

1. 引用 loop 变量 A 就像 environment 变量用 %A% 而不是 %%A 和
2. 在使用( 和) 定义的命令块中引用环境 变量定义/设置需要使用延迟扩展 之前通过命令行@987654328 启用@ 并使用!sourcedir! 和!outputdir! 而不是%sourcedir% 和%outputdir%，它们已经被环境 变量sourcedir 和outputdir 的当前值替换（此处为空字符串）之前定义）当 Windows 命令处理器在第一次执行命令 FOR 之前解析整个命令块时。
3. %%A 在结尾的右括号后对于 Windows 命令解释器是未知的，因此由于语法错误导致批处理退出。

但是，比您的代码需要首先创建带有文件夹路径的文本文件更好的是使用以下代码：

@echo off
for /D %%D in ("G:\Animation\ToConvert\*") do (
    if exist "%%D\Main\*.mkv" (
        echo Processing %%D ...
        if not exist "%%D\Converted\*" md "%%D\Converted"
        for %%I in ("%%D\Main\*.mkv") do (
            ffmpeg.exe -i "%%I" -s 640x480 -map 0 -c:v libx265 "%%D\Converted\%%~nxI"
        )
    )
)

带有参数/D 的外部FOR 仅查找文件夹G:\Animation\ToConvert 内的非隐藏子文件夹，并在循环变量D 中保存完整路径不以反斜杠结尾的子文件夹的名称。

IF 条件检查当前子文件夹中是否有一个文件夹 Main 包含 1 个或多个要处理的 *.mkv 文件。如果这个条件成立，

• 会输出一条信息消息以查看运行批处理文件的进度，
• 在当前子文件夹中，如果文件夹 Converted 尚不存在，则会创建该文件夹，
• 执行另一个 FOR 循环来处理在当前子文件夹的文件夹 Main 中找到的每个 *.mkv 文件。

循环变量I 保存当前*.mkv 文件的名称和完整路径。所以"%%I"可以用于输入文件，因为当前目录无关紧要，因为输入文件名带有完整路径。

对于输出文件，指定当前子文件夹中的文件夹Converted，并附加%%~nxI作为文件名和输入文件的文件扩展名作为输出文件的名称。

此批处理代码不需要延迟扩展，因为没有使用环境变量，只有循环变量D 和I。

为了完整起见，您的代码还使用包含逐行处理文件夹的文本文件，删除所有不必要的环境变量，以便在不使用命令 setlocal 和 endlocal 的情况下运行批处理文件。

@echo off
for /F "usebackq tokens=*" %%A in ("f.txt") do (
    if exist "%%A\Main\*.mkv" (
        echo Processing %%A ...
        if not exist "%%A\Converted\*" md "%%A\Converted"
        for %%I in ("%%A\Main\*.mkv") do (
            ffmpeg.exe -i "%%I" -s 640x480 -map 0 -c:v libx265 "%%A\Converted\%%~nxI"
        )
    )
)

要了解所使用的命令及其工作原理，请打开命令提示符窗口，在其中执行以下命令，并仔细阅读每个命令显示的所有帮助页面。

• echo /?
• for /?
• if /?
• md /?

顺便说一句：如果您想了解延迟扩展是什么以及此处不需要 setlocal 和 endlocal 的命令，请参阅 this answer 和链接的其他答案。

Answer 2

@Mofi 写了一个很棒的答案，他的两个代码都完美无缺。这只是我正在运行的一个更简单的版本，因为在该程序中检查的条件已经满足。

@echo off
for /F "tokens=*" %%A in (f.txt) DO (
        for %%F in (%%A\Main\*.mkv) DO ffmpeg -i "%%F" -s 640x480 -map 0 -c:v libx265 "%%A\Converted\%%~nxF"
)