批处理：比较文件大小

Question

我见过几种比较文件的不同方法，使用 COMP、FC 和其他一些方法，但我需要做的是基本的文件大小比较，如果文件较大，则在本地复制文件，到网络文件。

文件可以是 200kb 到 5gb 的任意大小。所以我真的只对文件大小感兴趣，而不是内容。

我希望通过登录脚本运行基本的 Dos 脚本。

Check local file A
Check remote file B
If file A is bigger than file B
  Copy B to A

Answer 1

FOR 循环扩展 z 将返回文件的大小（例如 %~zl）。 延迟变量扩展是此脚本的要求。此特定脚本仅在文件较大时复制，但如果大小完全不同，您可以通过将 GTR 更改为 NEQ 轻松更改它以复制文件。

@ECHO OFF
SETLOCAL ENABLEDELAYEDEXPANSION

SET REMOTE_DIR=\\SERVER\share\path\to\files
SET LOCAL_DIR=.

FOR /F %%f IN (files_to_compare.txt) DO (
    SET "REMOTE_FILE=%REMOTE_DIR%\%%~nxf"
    SET "LOCAL_FILE=%LOCAL_DIR%\%%~nxf"
    FOR %%r IN (!REMOTE_FILE!) DO (
        @ECHO [REMOTE] %%~nxr: %%~zr
        FOR %%l IN (!LOCAL_FILE!) DO (
            @ECHO [LOCAL] %%~nxl: %%~zl
            IF %%~zr GTR %%~zl (
                @ECHO %%~nxr: Remote file IS larger [%%~zr] ^> [%%~zl]
                COPY /Y "%%~r" "%%~l"
            ) ELSE (
                @ECHO %%~nxr: Remote file is not larger [%%~zr] ^<= [%%~zl]
            )
        )
    )
)