一次将一个文件复制到一个文件夹，其中有 100 个文件和 100 个文件夹要使用批处理文件复制

Question

我有两个文件夹CopyFrom 和CopyTo，其中CopyFrom 有100 个文本文件，名为1.txt…100.txt，在CopyTo 文件夹中我有100 个文件夹，名为F1…F100。现在，我想将CopyFrom 文件夹中的一个文件复制到CopyTo 中的一个文件夹中，这样F1 将包含1.txt，F2 将包含2.txt，...，F100 将包含100.txt文件。

我知道复制所有可以使用For /d %%a in (C:\Users\me\Desktop\ShortCuts\*) do xcopy "C:\Users\me\Desktop\Time.xls" "%%a" 之类的文件夹，但我找不到将不同文件复制到不同文件夹的方法。

我可以回显CopyFrom 文件夹中的所有文件(For %%a in (C:\Users\me\Desktop\ShortCuts\*) Echo "%%a")，也可以回显CopyTo 文件夹中的所有文件夹，但无法弄清楚如何同时使用这两个文件来获得我想要的东西。

Answer 1

@echo off
    setlocal enableextensions disabledelayedexpansion

    rem Configure paths
    set "copyFrom=c:\somewhere"
    set "copyTo=c:\anotherPlace"

    rem Generate two lists, one with files and one with folders
    dir /b /a-d "%copyFrom%\*" > "%temp%\copyFromFiles.txt"
    dir /b /ad  "%copyTo%\*"   > "%temp%\copyToFolders.txt"

    rem Assign each list as input to two streams and start processing    
    9< "%temp%\copyFromFiles.txt" 8< "%temp%\copyToFolders.txt" (
        call :matchFromWithTo
    )

    rem Remove generated lists
    del "%temp%\copyFromFiles.txt"
    del "%temp%\copyToFolders.txt"

    rem End
    goto :eof

:matchFromWithTo
    rem Read file from stream 9 and leave if nothing read
    <&9 set /p "file="   || goto :eof 
    rem Read folder from stream 8 and leave if nothing read
    <&8 set /p "folder=" || goto :eof

    rem Do the copy (debug: we will only echo the command)
    echo copy "%copyFrom%\%file%" "%copyTo%\%folder%"

    rem Keep reading until all files or folders are processed
    goto :matchFromWithTo

Answer 2

假设源位置仅包含文件1.txt 至100.txt，而目标位置已包含所有F1 至F100 目录，则以下代码 sn-p 可能适合您：

@echo off
setlocal EnableExtensions DisableDelayedExpansion

rem // Define constants here:
set "Pattern=*.txt"
set "CopyFrom=."
set "CopyTo=D:\Target"

for %%F in ("%CopyFrom%\%Pattern%") do (
    ECHO copy "%%~F" "%CopyTo%\F%%~nF\"
)

endlocal
exit /B

没有对目标位置进行枚举，复制目标只是从源文件名派生而来。

测试完脚本后，去掉大写的ECHO命令就可以真正复制文件了！