获取早于 x 天的空文件夹列表

Question

我需要获取给定位置的空文件夹列表，该列表早于 x 天。使用“forfiles”我可以获取所有旧文件夹，但不能获取空文件夹。使用“for”我可以获得所有空文件夹，但我似乎无法设置旧文件夹。

获取空文件夹：

@for /r "c:\FileStore" /d %F in (.) do @(dir /b "%F" | findstr "^" >nul || echo %~fF)

获取旧文件夹：

 ForFiles /p "C:\FileStore" /s /d -3 /c "cmd /c if @isdir==TRUE echo @path"

如何组合这两个命令？

Answer 1

您需要将findstr "^" 部分的引号转义为forfiles。有\" 的方法，但我不建议这样做，因为命令解释器cmd 仍然可以识别"（尽管用户Ben Personick 显示了如何在his answer 中执行此操作）。无论如何，我会改用0x22 来隐藏cmd 的引号，如下所示：

forfiles /S /P "C:\FileStore" /D -3 /C "cmd /C if @ISDIR == TRUE (dir /B /A @PATH | findstr 0x22^0x22 > nul || echo @PATH)"

您也可以使用find /V ""，而不是findstr "^"：

forfiles /S /P "C:\FileStore" /D -3 /C "cmd /C if @ISDIR == TRUE (dir /B /A @PATH | find /V 0x220x22 > nul || echo @PATH)"

但最简单的方法是使用set /P：

forfiles /S /P "C:\FileStore" /D -3 /C "cmd /C if @ISDIR == TRUE (dir /B /A @PATH | set /P _= || echo @PATH)"

N. B.：
forfiles 只考虑上次修改的日期（不是时间），而不考虑创建日期/时间。

Answer 2

您最大的障碍是转义 FindStr 中的双引号，而 Carrot 也需要加倍（否则它将阻止以下引号被转义。）

嗯，奇怪，我以为你要求删除这些目录，因为你没有，我会修改它。

ForFiles /P "c:\FileStore" /d -3 /C "CMD /C if @isdir==TRUE ( DIR /B @Path | FindStr \"^^\" >NUL || ECHO Empty Folder: @Path )"

此外，由于您只是在寻找列表，因此杀死 FindStr 的输出确实有意义，所以我添加了 >Nul 回来。

再次不确定我是如何想到你想删除超过 3 天的空文件夹的，因为没有这样的要求，关于需要重新运行命令的部分是没有实际意义的，我'已经删除了现在。