用于将文本文件中列出的文件从文件夹及其子文件夹复制到新位置的批处理脚本

Question

我想要一个批处理文件将文本文件中列出的所有文件从一个目标复制到另一个目标。源目标可能有多个子文件夹，我希望批处理在每个子文件夹中搜索文件名。

我不想复制文件夹本身，只复制文件。

我有以下代码，但它无法识别 (%file_list%)

set src=c:\files\sourcefolder\
set dst=c:\files\destinationfolder\
set file_list=c:\\files\files.txt

for /r "%src%" %%i in (%file_list%) do copy "%%i" "%dst%" >notcopied.txt

我还希望该文件写入一个名为“notcopied.txt”的文本文件，这样我就可以查看源文件夹中是否没有任何必需的文件。我希望将该文件写入目标文件夹。

例如：

files.txt contains
File1.pdf
File2.pdf
File3.pdf

源文件夹包含

File1.pdf
File2.pdf

notcopied.txt 将会显示

File3.pdf

感谢您的任何见解。

Answer 1

首先，您需要启用扩展命令行

SETLOCAL ENABLEEXTENSIONS

因此您可以使用扩展的 FOR 循环。二、需要开启环境变量的延迟扩展

SETLOCAL ENABLEDELAYEDEXPANSION

这样您就可以检查是否稍后找到搜索的文件。

结果如下：

@echo off
SETLOCAL ENABLEEXTENSIONS
SETLOCAL ENABLEDELAYEDEXPANSION

SET src=.\sourcefolder\
SET dst=.\destinationfolder\
SET file_list=.\files.txt

FOR /F %%f IN (%file_list%) DO (
    SET found=false
    FOR /F "usebackq" %%s IN (`where /R %src% %%f`) DO (
        SET found=true
        echo "%%s => %dst%\%%f"
        @copy /y "%%s" "%dst%\%%f" 
    )
    IF "!found!" == "false" (
        echo %%f is not found!
    )
)

ENABLEDELAYEDEXPANSION 在这里需要变量%found%，没有它%found% 将永远是false。 此外，要在运行时扩展环境，您必须使用!found! 语法。

你可以这样称呼它

batch.bat > result.log

结果将写入文件result.log

---

更新：这是不带变量 found 的 bacth 版本，并带有 @aschipfl 的建议：

@echo off
SETLOCAL ENABLEEXTENSIONS ENABLEDELAYEDEXPANSION

SET "src=.\sourcefolder\"
SET "dst=.\destinationfolder\"
SET "file_list=.\files.txt"

FOR /F "usebackq eol=| delims=" %%f IN ("%file_list%") DO (
    rem just searching to find out existense of file
    WHERE /Q /R "%src%" "%%f"
    IF "!ERRORLEVEL!" == "0" (
        FOR /F "usebackq eol=| delims=" %%s IN (`WHERE /R "%src%" "%%f" 2^> nul`) DO (
            echo "%%s => %dst%\%%f"
            @copy /y "%%s" "%dst%\%%f" 
        )
    ) ELSE (
        echo %%f is not found!
    )
)

此版本可以处理文件名中带有space 符号的文件。
但两种解决方案都有相同的限制：sourcefolder 的名称中不能包含任何空格。出于某种原因，命令 WHERE /R "%src%" "%%f" 不起作用，而 WHERE /R %src% "%%f" 则按预期工作。

---

UPDATE2：这是产生result.log的版本：

@echo off
SETLOCAL ENABLEEXTENSIONS ENABLEDELAYEDEXPANSION

SET "src=.\sourcefolder\"
SET "dst=.\destinationfolder\"
SET "file_list=.\files.txt"
SET "out=.\result.log"
echo > %out%

FOR /F "usebackq eol=| delims=" %%f IN ("%file_list%") DO (
    rem just searching to find out existense of file
    WHERE /Q /R %src% "%%f"
    IF "!ERRORLEVEL!" == "0" (
        FOR /F "usebackq eol=| delims=" %%s IN (`WHERE /R %src% "%%f"`) DO (
            echo "%%s => %dst%\%%f" >> %out%
            @copy /y "%%s" "%dst%\%%f" 
        )
    ) ELSE (
        echo %%f is not found! >> %out%
    )
)