尝试编写调用批处理文件但不断收到“找不到”错误

Question

我正在尝试编写一个批处理文件来调用另一个替换目录中的两个文件的批处理文件。这是我的代码：

set mmcIpath="C:"*"\mmc-stable-win32\MultiMC\instances"

call C:\%mmcIpath%\spc_we_replace_CED+CEDU.bat

每当我设置临时环境变量时，它都会说找不到目录。

--附加信息--

我运行一个名为 MultiMC5 的 Minecraft 启动器；它具有运行命令的功能 - 但由于某种原因只有一个命令。所以我想让它调用一个批处理文件来运行多个命令。

我的主批处理文件位于“C:...\MultiMC\instances”中，但我希望程序能够调用它。它不能，因为它在名为“CED (210 mods-)”的子目录中工作。所以我在子目录中放置了另一批以调用主目录（我想对名为“CEDU (300+ mods-)”的第二个子目录执行相同的操作）。我收到此错误：“系统找不到指定的路径。”。它发生在我设置路径时。

我使用的是 Windows 8.1，并搜索了有关如何使用通配符和如何使用 FOR 循环的提示，但没有一种通配符方法对我有用，而且我根本无法理解 FOR 循环。我还尝试删除和添加引号之类的内容以尝试修复它，但这也不起作用。

我的问题：

set 命令是否与通配符兼容，如果是，我该如何让它工作？

Answer 1

看起来您的问题是主批处理文件可以在任何驱动器上，并且您想使用相对于主批处理文件位置的路径调用其他批处理文件。对吗？

您可以使用%~d0 获取驱动器，使用%~p0 获取路径，使用%~dp0 获取驱动器+路径。请参阅下面的示例并执行存储在几个不同目录中的这个小批处理文件：

@echo off
echo Batch is stored on drive %~d0
echo in the directory %~p0
echo resulting in path %~dp0

因此，您可以使用由 %0 引用的参数 0，该参数始终包含具有完整路径的批处理文件的名称，使用上面在命令提示符窗口中输入 for /? 显示的命令 FOR 的帮助中解释的语法来调用另一个批处理文件的路径取决于主批处理文件的路径。

Answer 2

现在我们这里有一个经典的 XY problem - 被问及解决方案，而不是根本问题。

这是一个可能的解决方案：

@ECHO OFF
SETLOCAL
set mmcIpath="C:"*"\mmc-stable-win32\MultiMC\instances"
set "mmcIpath=U:\\.*\\mmc-stable-win32\\MultiMC\\instances"
SET "targetbat=spc_we_replace.bat"

FOR /f "delims=" %%a IN (
  'dir /b/s /ad "%mmcIpath:~0,3%"^|findstr /e /i /r /c:"%mmcIpath%" '
  ) DO (
 IF EXIST "%%a\%targetbat%" (
  ECHO CALL "%%a\%targetbat%"
  ECHO GOTO nextstep
 )
)

:nextstep

GOTO :EOF

我保留了mmcIpath 的原始设置，并将其替换为适合我系统的表单。

方法是执行dir/s/b/ad 命令（目录，基本格式，仅带有子目录，目录名称）并使用findstr 对其进行过滤。我选择了开关/i（不区分大小写）/e（必须以字符串结尾）/r正则表达式/c:（以下是要匹配的一个字符串）。

正则表达式是按照findstr的规则构造的——\如果要用作字面量需要加倍； .* 表示“任意数量的任意字符”

这应该提供通过过滤器的文字目录名称列表。在找到的目录中查找文件名，call 目标文件（如果找到）。出于测试目的，所需的 CALL 命令仅是 ECHOed。 验证命令正确后，将ECHO CALL更改为CALL以实际执行文件。

如果需要，下面的ECHO GOTO 表明在找到第一个目标文件后可以中断循环。您还没有指明是只运行第一个目标还是运行所有找到的目标。

---

这是我的测试源。我使用U: 来测试数据。您的系统可能会有所不同。

@ECHO OFF
SETLOCAL
SETLOCAL ENABLEDELAYEDEXPANSION
set "mmcIpath=\mmc-stable-win32\MultiMC\instances"
FOR /l %%a IN (1,1,4) DO MD u:\%%a%mmcIpath% 2>nul
FOR /l %%a IN (2,2,4) DO COPY NUL u:\%%a%mmcIpath%\spc_we_replace.bat 2>NUL >nul
ENDLOCAL
ENDLOCAL


@ECHO OFF
SETLOCAL
set mmcIpath="C:"*"\mmc-stable-win32\MultiMC\instances"
set "mmcIpath=U:\\.*\\mmc-stable-win32\\MultiMC\\instances"
SET "targetbat=spc_we_replace.bat"

FOR /f "delims=" %%a IN (
  'dir /b/s /ad "%mmcIpath:~0,3%"^|findstr /e /i /r /c:"%mmcIpath%" '
  ) DO (
 IF EXIST "%%a\%targetbat%" (
  ECHO CALL "%%a\%targetbat%"
  ECHO GOTO nextstep
 )
)

:nextstep

GOTO :EOF

请注意，第一部分只是将u:\1\mmc-stable-win32\MultiMC\instances 建立到u:\4\mmc-stable-win32\MultiMC\instances，然后在u:\2\mmc-stable-win32\MultiMC\instances 和u:\4\mmc-stable-win32\MultiMC\instances 中创建一个虚拟文件spc_we_replace.bat。

第二部分分配给mmcIath的字符串是根据findstr的语法规则-每个\加倍，.*表示“任意数量的任意字符”。您必须修改该字符串以适合您的系统。请注意，"%mmcIpath:~0,3%" 无偿地从字符串中获取前 3 个字符。就我而言，那将是U:\。 YMMV