如何批量解析xml文件（CMD）

Question

你能帮我列出这个文件中的浏览器吗 http://techpatterns.com/downloads/firefox/useragentswitcher.xml 成txt文件，用%tab%分隔符分隔？

应该有 3 或 4 列：

1) 示例数据中的文件夹描述：<folder description="Browsers - Windows">

2) 示例数据中的浏览器类型：<folder description="Legacy Browsers">

3) 示例数据中的用户代理：<useragent description="Avant Browser 1.2" useragent="Avant Browser/1.2.789rel1 (http://www.avantbrowser.com)" app

在这里我看到第一个问题，因为某些浏览器不在文件夹 <folder description="Legacy Browsers">" 中，而是在 <separator/> 下

所以第一列应该定义系统，第二列是类型，第三列是浏览器。

下一个问题是 Devises 文件夹包含一个文件夹。

@echo off 
Setlocal EnableDelayedExpansion
SET file=useragentswitcher.xml
SET delim="

FOR /F "tokens=* skip=1" %%F IN (!file!) DO (
  REM echo %%F
  call :parse "%%F" > temp.txt
  FOR /F "tokens=1,2,3,4,5,6,7 skip=1 delims=" %%A IN (temp.txt) DO (
    IF "%%A"=="folder" (
      SET /A level=!level!+1
      echo Level:!level!
      ) ELSE IF "%%A"=="/folder" (
          SET /A level=!level!-1
          echo Level:!level!
        )

   echo A:%%A
  )
  pause
)

exit /b

:parse
Setlocal EnableDelayedExpansion
  SET A=%*
  REM REMOVE double paranthesis and <> 
  SET A=!A:~2,-2!
  REM replace double qoutes
  SET A=!A:"=µ!
  FOR /F "tokens=1,2 delims=µ=" %%A IN ("!A!") DO (
    SET first=%%A
    SET second=%%B
    echo !first!
    FOR /F "tokens=1,2 delims= " %%A IN ("!first!") DO (
      echo %%A
      echo %%B
    )
    echo !second!
  )
endlocal
exit /b

这会解析该行的一个标签，我现在将使用它。

Answer 1

看来你应该能找到比批处理更好的工具来解析 XML...

但我相信下面的代码就是您要找的。

由于文件夹的数量不同，我交换了输出中列的顺序。我将浏览器描述放在首位，然后是文件夹，每列一个。这允许固定每列的定义。

我使用 jeb 的答案中的信息将 " 包含为 FOR 分隔符。

编辑 - 我简化了代码

注意 - 第一次尝试是为了处理使用 Internet Explorer 检索到的 XML 副本而编写的。从那以后，我发现 IE 改变了文件的格式。此代码高度依赖于文件的确切格式，因此它不适用于原始 XML。它还作为示例说明为什么批处理是解析 XML 的糟糕选择

@echo off
setlocal enableDelayedExpansion

::Define the files to use - change as needed
set input="test.xml"
set output="result.txt"

::The assignment below should have exactly one TAB character between = and "
set "TAB=   "

set cnt=0
set "folder0="
>%output% (
  for /f usebackq^ tokens^=1^,2^ delims^=^=^" %%A in (%input%) do (
    for %%N in (!cnt!) do (
      if "%%A"=="- <folder description" (
        set /a cnt+=1
        for %%M in (!cnt!) do set "folder%%M=!folder%%N!%TAB%%%B"
      )
      if "%%A"=="  </folder>" (
        set /a cnt-=1
      )
      if "%%A"=="  <useragent description" (
        echo %%B!folder%%N!
      )
    )
  )
)

如果! 出现在任何描述中，代码将失败，因为延迟扩展会破坏包含! 的任何 FOR 变量的扩展。我检查了，您的文件在任何描述中都不包含!。

可以修改代码以处理描述中的!，但它会变得更加复杂。它需要打开和关闭延迟扩展，并在 ENDLOCAL 屏障中保存变量值。

以上代码高度依赖于 XML 的格式。如果非标准破折号被删除，或者空白排列发生变化，它将失败。

以下变体更加健壮，但仍要求每一行都包含一个 XML 标记。

@echo off
setlocal enableDelayedExpansion

::Define the files to use - change as needed
set input="test.xml"
set output="result.txt"

::The assignment below should have exactly one TAB character between = and "
set "TAB=   "

set cnt=0
set "folder0="
>%output% (
  for /f usebackq^ tokens^=1^,2^ delims^=^=^" %%A in (%input%) do (
    for %%N in (!cnt!) do (
      set "test=%%A"
      if "!test:<folder description=!" neq "!test!" (
        set /a cnt+=1
        for %%M in (!cnt!) do set "folder%%M=!folder%%N!%TAB%%%B"
      )
      if "!test:</folder>=!" neq "!test!" (
        set /a cnt-=1
      )
      if "!test:<useragent description=!" neq "!test!" (
        echo %%B!folder%%N!
      )
    )
  )
)

编辑 - 最后一个版本

这里有一个可以处理数据中!的版本。我在输出中添加了一个附加列。第一列仍然是浏览器描述。第二列是用户代理字符串。其余列是文件夹。该解决方案使用延迟扩展切换技术。它还使用额外的 FOR /F 来跨 ENDLOCAL 屏障保留变量值。

@echo off
setlocal disableDelayedExpansion

::Define the files to use - change as needed
set input="test.xml"
set output="result.txt"

::The assignment below should have exactly one TAB character between = and "
set "TAB=   "

set cnt=0
set folder0=""
>%output% (
  for /f usebackq^ tokens^=1-4^ delims^=^=^" %%A in (%input%) do (
    set "test=%%A"
    set "desc=%%B"
    set "agent=%%D"
    setlocal enableDelayedExpansion
    for %%N in (!cnt!) do (
      if "!test:<folder description=!" neq "!test!" (
        set /a cnt+=1
        for %%M in (!cnt!) do for /f "delims=" %%E in ("!folder%%N!") do (
          endlocal
          set "folder%%M=%%~E%TAB%%%B"
          set "cnt=%%M"
        )
      ) else if "!test:</folder>=!" neq "!test!" (
        endlocal
        set /a cnt-=1
      ) else if "!test:<useragent description=!" neq "!test!" (
        echo !desc!%TAB%!agent!!folder%%N!
        endlocal
      ) else endlocal
    )
  )
)

Answer 2

检查xpath.bat - 可以通过给定的xpath表达式从xml获取值的脚本：

call xpath.bat "useragentswitcher.xml" "//folder/@description"

Answer 3

回复你的评论How should I use double quotes as delimiter?

只需使用表格

FOR /F tokens^=1^,2^ delims^=^" %%B IN ("%%A") DO

这是如何工作的？
通常不能将引号字符用作分隔符。
这是唯一已知的解决方法，重要的是缺少围绕 FOR/F 选项的 正常 引号。
但必须将选项仅解析为一个标记，因此您需要转义所有标准批处理解析器分隔符（空格制表符 =,;）。
引号不是批处理分隔符，但也需要转义，以避免行的其余部分被引用，然后解析器将失败。
但是您可以将^" 更改为""，因为第二个引号将被忽略。

FOR /F tokens^=1^,2^ delims^="" %%B IN ("%%A") DO ...