如何在批处理脚本中捕获 powershell 错误？

Question

目前，我正在使用此脚本将yyyyMMdd 格式的日期转换为dd/MM/yyyy 格式。

for /f "delims=" %%a in ('powershell -Command "& {([datetime]::parseexact('%testDate%','yyyyMMdd',[System.Globalization.CultureInfo]::InvariantCulture)).ToString('dd/MM/yyyy')}"') do SET testDate=%%a

当我在 Powershell IDE 中为 %testDate% 变量输入无效字符/日期时间结构时，它会抛出错误消息 "String was not recognized as a valid DateTime"。

但是，在批处理脚本中，它只会返回一个空的 testDate 变量。它还返回errorlevel = 0。

如何在批处理脚本中从 powershell 返回错误消息？

---

完整脚本

@echo off
setlocal enabledelayedexpansion
REM Get user's inputs
:beginning
SET /p testDate="Please enter the date in yyyyMMdd format (e.g., 20171128)" || goto beginning
if /I "%testDate%"=="t" (
    for /f "delims=" %%a in ('powershell -Command "& get-date -format 'dd/MM/yyyy'"') do SET testDate=%%a
) ELSE (
    if /I "%testDate%"=="yt" (
        for /f "delims=" %%a in ('powershell -Command "& get-date (get-date).AddDays(-1) -format 'dd/MM/yyyy'"') do set testDate=%%a
    ) ELSE (
        for /f "delims=" %%a in ('powershell -Command "& {([datetime]::parseexact('%testDate%','yyyyMMdd',[System.Globalization.CultureInfo]::InvariantCulture)).ToString('dd/MM/yyyy')}"') do SET testDate=%%a
        REM Testing 
        echo !testDate!
        echo Yes!
    )
)
REM Testing 
echo !testDate!
echo !errorLevel!
pause

Answer 1

来自[datetime]::parseexact 的错误消息以多行文本形式返回，导致set testData=%%a 被多次调用。您可以通过单独运行命令来看到这一点。

例如。

c:\Temp> for /f "delims=" %a in ('powershell -Command "& {([datetime]::parseexact('%testDate%','yyyyMMdd',[System.Globalization.CultureInfo]::InvariantCulture)).ToString('dd/MM/yyyy')} "') do SET testDate=%a

输出：

C:\Temp> SET testDate=使用“3”个参数调用“ParseExact”异常：“字符串未被识别为有效
C:\Temp> SET testDate=DateTime。"
C:\Temp> SET testDate=行：1 字符：4
C:\Temp> SET testDate=+ & {([datetime]::parseexact('使用 3 个参数调用 ParseExact 的异常 ...
C:\Temp> SET testDate=+ ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~ ~~~~~~~~~~~
C:\Temp> SET testDate= + CategoryInfo : NotSpecified: (:) [], MethodInvocationException
C:\Temp> SET testDate= + FullyQualifiedErrorId : FormatException
C:\Temp> 设置测试日期=

要解决此问题，您需要在遇到错误时控制返回消息。

可以使用try/catch 语句来实现：

@echo off
setlocal enabledelayedexpansion
REM Get user's inputs
:beginning
SET /p testDate="Please enter the date in yyyyMMdd format (e.g., 20171128)" || goto beginning
if /I "%testDate%"=="t" (
    for /f "delims=" %%a in ('powershell -Command "& get-date -format 'dd/MM/yyyy'"') do SET testDate=%%a
) ELSE (
    if /I "%testDate%"=="yt" (
        for /f "delims=" %%a in ('powershell -Command "& get-date (get-date).AddDays(-1) -format 'dd/MM/yyyy'"') do set testDate=%%a
    ) ELSE (
        for /f "delims=" %%a in ('powershell -Command "& {try { ([datetime]::parseexact('%testDate%','yyyyMMdd',[System.Globalization.CultureInfo]::InvariantCulture)).ToString('dd/MM/yyyy') } catch { return $_.Exception.Message }} "') do SET testDate=%%a
        REM Testing 
        echo !testDate!
        echo Yes!
    )
)
REM Testing 
echo !testDate!
echo !errorLevel!
pause

Answer 2

if not defined testdate (echo Invalid date supplied)

或

if not defined eventdate (echo Invalid date supplied %testdate%)

或

if not defined eventdate (echo Invalid date supplied %testdate%&goto someplace)

取决于具体情况。你确定testdate 需要修改吗（第一种情况） - 我怀疑testdate 保持原样而eventdate 根本没有设置。