配置工作编号以包含前缀、年份、月份和下一个序列号

Question

我使用的是 Excel 2013（64 位）。

我目前正在开发一个用于记录事件的用户表单。但是，我无法在 VBA 中解决如何提出代码，该代码将导致上一行中的下一个可用数字填充用户表单中的 INC 数字文本框（ADD_txtSEC_INC_No）（然后相应地更新电子表格）。

结束格式应显示为 IncYYYYMM-00000 - 例如：Inc201603-00456（这正是我需要的）

我目前有一个代码（如下），它会显示下一个数字，但它不是所需的格式。 Sample of New form in development

Private Sub UserForm_Initialize()
'** SECURITY INCIDENT NUMBER IN TEXTBOX
'**WORKS

    Me.ADD_txtSEC_INC_No.Enabled = True
    Dim irow As Long
    Dim ws As sw_SecIncidentDetails
    Set ws = sw_SecIncidentDetails

'find last data row from database'
   irow = ws.Cells(Rows.Count, 1).End(xlUp).Row

   Me.ADD_txtSEC_INC_No.Text = ws.Cells(irow, 1).value + 1

End Sub

其他信息 当这个表格上线时，我需要让它从以前的号码继续，例如，如果我们当前工作表上的 Inc 号码，在 A 行是 Inc201603-00456，那么我需要你的初始化表单时转到下一个 Inc 编号的代码，例如 Inc201603-00457 我们不能从 0000 开始编号，因为这会将序列从先前的条目中排除。 抱歉，如果这听起来令人困惑。

在 B 列中，单元格由一个名为 ADD_Date_Recorded_TXT 的文本框填充，该文本框已编码：

       Me.ADD_Date_Recorded_TXT.value = Format(Now, "dd/mm/yyyy")

我之所以提到这一点，是因为 David 下面的解决方案似乎将日期格式更改为 mm/dd/yyyy（不明白为什么这样做） - 我需要所有日期都保持 dd/mm/yyyy 格式.

我只是想我会在“附加信息”中解决上述这些问题，而不是单独回复每个问题

Answer 1

我发现使用最后一行来构建新 id 非常危险。如果第一个列是未排序的，您最终可能会得到重复的标识符。 所以我会首先在第一列中搜索最大的数字，然后增加那个数字，最后格式化一个新的标识符：

Private Sub UserForm_Initialize()
'** SECURITY INCIDENT NUMBER IN TEXTBOX
'**WORKS

    Me.ADD_txtSEC_INC_No.Enabled = True
    Dim nextNumber As Long
    Dim nextId As String
    Dim ws As sw_SecIncidentDetails
    Set ws = sw_SecIncidentDetails

   ' get the next record number from the first column
   nextNumber = GetNextRecordNumber(ws.UsedRange.Columns(1))

   ' build the new record id
   nextId = "Inc" & Format(Now, "yyyymm") & Format(nextNumber, "-00000")

   Me.ADD_txtSEC_INC_No.text = nextId

End Sub

Private Function GetNextRecordNumber(source As Range) As Long
  Dim max$, v
  For Each v In source.value
    If InStr(1, v, "Inc") = 1 And v > max Then max = v
  Next
  If max <> Empty Then GetNextRecordNumber = Split(max, "-")(1) + 1
End Function

Answer 2

据我了解，您的前一行有一个类似 Inc201603-00455 的事件编号，您需要为您的新行生成 Inc201603-00456 吗？如果是这样，请尝试将最后一行替换为：

Me.ADD_txtSEC_INC_No.Text = "Inc" & Year(Date) & Format(Month(Date), "00") & "-" & Format(Split(ws.Cells(irow, 1).value, "-")(1) + 1, "00000")

这将以您所需的格式组装您需要的所有片段。但这假设您想要今天的日期，而不是从上一行中删除日期。如果你真的想从上一行复制日期，那么你可以使用它：

Me.ADD_txtSEC_INC_No.Text = Split(ws.Cells(irow, 1).value, "-")(0) & "-" & Format(Split(ws.Cells(irow, 1).value, "-")(1) + 1, "00000")

我们正在使用 Split 函数来划分旧的事件编号，并使用连字符作为分隔符。所以第 (0) 部分是“Inc201603”，第 (1) 部分是作为文本字符串的数字“00456”。但是一旦你用它进行数学运算 (+1)，这个值就会变成一个纯数字“456”，这就是我们使用 Format 函数再次给它一个五位数掩码的原因。

Answer 3

为保证下一个可用号码，您应该COUNTIF A 列中以前的 IncYYYYMM-nnnnn 号码。

Private Sub UserForm_Initialize()
'** SECURITY INCIDENT NUMBER IN TEXTBOX
'**WORKS

    Me.ADD_txtSEC_INC_No.Enabled = True
    Dim i As Long, str As String
    Dim ws As sw_SecIncidentDetails
    Set ws = sw_SecIncidentDetails

    'find last data row from database'
    str = Format(Date, "\I\n\cyyyymm")
    i = Application.CountIf(ws.Columns(1), str & Chr(42))

    Me.ADD_txtSEC_INC_No.Text = str & Format(i, "-00000")

End Sub

这将动态工作。下个月计数将在 Inc201604-00000 重新开始。