在 Dos 脚本中查找和比较？

Question

我运行了一个第三方命令，它在执行后显示如下错误级别：

 return code: 33
 return code: 1
 return code: 4
 return code: 5 

我将命令的结果通过管道传输到日志文件中。所以 test.log 会有任意组合 以这些行为例：

 return code: 33
 return code: 1

在我的脚本中，我想检查日志文件的内容以及入口代码是否为任何内容 但是1（一表示成功）我会做一个动作

我认为 find 命令是我必须使用的，但不确定使用什么语法？ 基本上逻辑应该是，查看日志文件，如果错误代码不是 1，请执行一些操作。

谁能建议如何编写代码来检查这个？

提前致谢 马特

Answer 1

以下将判断日志文件中是否存在至少一个非1的返回码：

findstr /rxc:"return code: [0-9]*" test.log | findstr /ev ": 1" >nul && echo Do something

以下循环允许您对每个非 1 返回码执行操作：

for /f "tokens=3 delims=: " %%A in (
  'findstr /rxc:"return code: [0-9]*" test.log ^| findstr /ev ": 1"'
) do (
  echo return code = %%A
  echo So do something about it
)

如果因为多余的空格不匹配，试试：

findstr /rxc:" *return code: *[0-9]* *" test.log | findstr /ev ": 1" >nul && echo Do something

Answer 2

给定一个文件 test.log，其中包含：

return code: 33
return code: 1
return code: 4
return code: 5

分析 test.log 的批处理脚本如下所示：

@echo off
for /F "delims=" %%i in ('findstr /e /v ": 1" test.log') do (
    echo %%i
    rem do some other command instead of echo
)

Findstr 在行尾的 /e 开关匹配模式和 /v 开关选择除匹配之外的所有内容。结果将是：

return code: 33
return code: 4
return code: 5

在下方编辑

如果文本内容如下所示，我们也想对文本alternate: 1做一些事情，

return code: 33
return code: 1
return code: 4
return code: 5
alternate: 1

我们会做出如下细微的改变：

@echo off
for /F "delims=" %%i in ('findstr /e /v "return code: 1" test.log') do (
    echo %%i
    rem do some other command instead of echo
)

这样我们提取除return code: 1之外的所有内容。

编辑 2

要在第一个实例之后退出循环，请执行以下操作：

@echo off
for /F "delims=" %%i in ('findstr /e /v "return code: 1" test.txt') do (
    echo %%i
    goto :eof
)
:eof