如何编写多维 MS SQL 连接以返回常见的渐进式数据链接

Question

我正在尝试找出一种有效的方法来识别基于迭代多连接的公共数据点。例如：

INPUT
-----
ID1 ID2
X   Y
Y   Z
Z   1
A   B
C   D
1   A
B   A

X 连接到 Y。Y 连接到 Z。Z 连接到 1。 因此，X 和 1 通过 Y 和 Z 连接（“共同”），以此类推，以创建以下输出：

OUTPUT
------
ID1 ID2 CommonKey
X   Y   1
Y   Z   1
Z   1   1
A   B   1
C   D   2
1   A   1
B   A   1

如果数据点以任何方式相互关联，无论是当前的还是未来的，它们都应该被赋予相同的“CommonKey”

我已经研究过使用 CTE 来解决这个问题，但到目前为止还没有成功。

Answer 1

所以，我可以使用 WHILE 循环。

DECLARE @Tbl TABLE (Id1 NVARCHAR(10), Id2 NVARCHAR(10))
DECLARE @Result TABLE (Id1 NVARCHAR(10), Id2 NVARCHAR(10), CommonKey INT)
DECLARE @RootCounter INT = 1
DECLARE @TempKey NVARCHAR(10)

INSERT INTO @Tbl
VALUES
('X', 'Y'),     
('Y', 'Z'), 
('Z', '1'), 
('A', 'B'), 
('C', 'D'), 
('1', 'A'), 
('B', '10'),    
('D', '4'), 
('8', '9'), 
('9', 'J'),     
('J', 'R')

IF OBJECT_ID('tempdb..#RootItems') IS NOT NULL DROP TABLE #RootItems
SELECT
    T.Id1 ,
    T.Id2,
    ROW_NUMBER() OVER (ORDER BY (SELECT NULL))  AS RowId
INTO #RootItems
FROM
    @Tbl T
WHERE
    T.Id1 NOT IN (SELECT I.Id2 FROM @Tbl I)         



WHILE (@RootCounter <= (SELECT COUNT(1) FROM #RootItems))
BEGIN
    IF OBJECT_ID('tempdb..#RootTemp') IS NOT NULL DROP TABLE #RootTemp
    IF OBJECT_ID('tempdb..#CurrTemp') IS NOT NULL DROP TABLE #CurrTemp
    SELECT * INTO #RootTemp FROM #RootItems
    WHERE RowId = @RootCounter

    SELECT Id1,Id2,@RootCounter AS CommonKey INTO #CurrTemp FROM #RootTemp
    INSERT INTO @Result  SELECT * FROM #CurrTemp

    WHILE 1 = 1
    BEGIN   

        IF OBJECT_ID('tempdb..#NextTemp') IS NOT NULL   
            DROP TABLE #NextTemp    

        SELECT Id1,Id2,@RootCounter AS CommonKey INTO #NextTemp FROM @Tbl WHERE Id1 = (SELECT C.Id2 FROM #CurrTemp C)
        IF EXISTS (SELECT 1 FROM #CurrTemp C INNER JOIN #NextTemp N ON C.Id1 = N.Id2) OR NOT EXISTS(SELECT 1 FROM #NextTemp)  BREAK

        INSERT INTO @Result SELECT * FROM #NextTemp
        DELETE FROM #CurrTemp
        INSERT INTO #CurrTemp SELECT * FROM #NextTemp
    END     

     SET @RootCounter += 1                 
END


SELECT * FROM @Result

结果：

Id1 Id2 CommonKey
X   Y   1
Y   Z   1
Z   1   1
1   A   1
A   B   1
B   10  1
C   D   2
D   4   2
8   9   3
9   J   3
J   R   3

Answer 2

使用 CTE 并添加另一个“RowId”以按链接顺序获取内容：

CREATE TABLE  Tbl  (Id1 NVARCHAR(10), Id2 NVARCHAR(10))

    INSERT INTO Tbl
    VALUES
    ('X', 'Y'),     
    ('Y', 'Z'), 
    ('Z', '1'), 
    ('A', 'B'), 
    ('C', 'D'), 
    ('1', 'A'), 
    ('B', '10'),    
    ('D', '4'), 
    ('8', '9'), 
    ('9', 'J'),     
    ('J', 'R'),
    ('D','B');




 WITH LinkList(Id1,Id2, CommonKey, RowId)
AS
(SELECT Id1, id2, row_number() Over (ORDER BY Id1) AS CommonKey, 1 As RowId FROM tbl WHERE Id1 Not in (select Id2 from tbl)
UNION ALL
 SELECT tbl.id1 as id1 , tbl.id2 as Id2 , LinkList.CommonKey as CommonKey, RowId + 1 as RowId
 FROM tbl 
 INNER JOIN LinkList
    On Linklist.Id2 = tbl.Id1)
    SELECT l.Id1, l.Id2 , l.CommonKey, k.MinKey, ISNULL (k.Minkey, l.CommonKey) AS NewCommonKey
    FROM LinkList l
    LEFT OUTER JOIN
    (SELECT x.CommonId, X.CommonKey, y.MinKey FROM 
    (SELECT Min(Id2) AS CommonId, CommonKey FROM LinkList WHERE ID2 IN
    (SELECT Id2
    FROM LinkList 
    GROUP BY Id2
    Having Count(CommonKey) > 1) 
    GROUP BY CommonKey) as X CROSS APPLY (SELECT MIN(CommonKey) as MinKey FROM LinkList WHERE Id2 = x.CommonId) AS y) AS k
    ON l.CommonKey = k.CommonKey    

    DROP Table Tbl

结果是：

Id1 Id2 CommonKey   MinKey  NewCommonKey
8   9   1   NULL    1
C   D   2   2   2
X   Y   3   2   2
Y   Z   3   2   2
Z   1   3   2   2
1   A   3   2   2
A   B   3   2   2
B   10  3   2   2
D   4   2   2   2
D   B   2   2   2
B   10  2   2   2
9   J   1   NULL    1
J   R   1   NULL    1

它需要另一个围绕它的选择和组来消除重复项， 但是您可以看到以这种方式合并的列表，请原谅我的格式化技巧。 这就是你所追求的吗？