社交网络的 neo4j 属性百分比

Question

如何计算社交网络所有连接的属性百分比？ 在这个特定的示例中，我想通过评估用户的交互（电话、短信）来计算用户的欺诈行为：

CREATE (Alice:Person {id:'a', fraud:1})
CREATE (Bob:Person {id:'b', fraud:0})
CREATE (Charlie:Person {id:'c', fraud:0})
CREATE (David:Person {id:'d', fraud:0})
CREATE (Esther:Person {id:'e', fraud:0})
CREATE (Fanny:Person {id:'f', fraud:0})
CREATE (Gabby:Person {id:'g', fraud:0})
CREATE (Fraudster:Person {id:'h', fraud:1})


CREATE
  (Alice)-[:CALL]->(Bob),
  (Bob)-[:SMS]->(Charlie),
  (Charlie)-[:SMS]->(Bob),
  (Fanny)-[:SMS]->(Charlie),
  (Esther)-[:SMS]->(Fanny),
  (Esther)-[:CALL]->(David),
  (David)-[:CALL]->(Alice),
  (David)-[:SMS]->(Esther),
  (Alice)-[:CALL]->(Esther),
  (Alice)-[:CALL]->(Fanny),
  (Fanny)-[:CALL]->(Fraudster)

当尝试查询时：

MATCH (a)-->(b)
WHERE b.fraud = 1
RETURN (count() / ( MATCH (a) -->(b) RETURN count() ) * 100)

我看到以下错误：

Invalid input '>': expected 0..9, '.', UnsignedHexInteger, UnsignedOctalInteger or UnsignedDecimalInteger (line 3, column 33 (offset: 66))
"RETURN (count() / ( MATCH (a) -->(b) RETURN count() ) * 100)"
                                 ^

Answer 1

此查询将返回每个欺诈的连接百分比：

MATCH (:Person)-[:CALL|:SMS]->(f:Person)
WITH TOFLOAT(COUNT(*))/100 AS divisor, COLLECT(f) AS fs
UNWIND fs AS f
WITH divisor, f
WHERE f.fraud = 1
RETURN f, COUNT(*)/divisor AS percentage

有了样本数据，结果是：

+----------------------------------------------+
| f                        | percentage        |
+----------------------------------------------+
| Node[13]{id:"h",fraud:1} | 9.090909090909092 |
| Node[6]{id:"a",fraud:1}  | 9.090909090909092 |
+----------------------------------------------+

此查询只需要对数据库进行一次扫描，并且明确说明节点标签和关系类型——以过滤掉数据库中可能存在的任何其他数据。

Answer 2

在您的 RETURN 部分中，您调用一个新查询：MATCH (a) -->(b) RETURN count()。

这在 Neo4j 中是不允许的，您应该使用 WITH 关键字进行子查询：

MATCH ()-->() 
WITH count(*) AS total
  MATCH ()-->(b)
  WHERE b.fraud = 1
  RETURN toFloat(count(*)) / total * 100

或者在您的情况下，因为您只想要数据库中的关系总数，您可以进行以下查询：

MATCH ()-->(b)
WHERE b.fraud = 1
RETURN toFloat(count(*)) / size(()-->()) * 100

更新

• 在密码查询中添加toFloat，否则除法会给出整数而不是浮点数