如何从关系或节点中获取 Neo4j GraphQL 中的日期？

Question

您好，下面是在 Neo4j GraphQL 的上下文中（所以我需要确保我在这里返回节点，而不是 Maps 或任何东西，我认为）。

我有节点Users 和Posts，用户可以在其中撰写或转发帖子。基本上帖子有created_date 字段，但是当用户“转发”该帖子时，我想知道该转发的时间。

典型的关系如下所示：

(u:User)-[r:WROTE]->(post:Post)

帖子创建日期字段的位置。当用户重新发布它时，基础帖子不会更改，他们只是向该帖子添加一个 REPOSTED 关系。像这样：

(u:User)-[r:REPOSTED]->(post2:Post)

当我想查看用户的帖子时，我想抓取他们撰写或转发的任何内容，并按照 post.created_date 的顺序（如果他们WROTE 帖子或REPOSTED 时间）进行排序如果他们转发了。

我不知道我应该在这里做什么，所以我尝试了这样的事情，但它没有及时编辑 repost_date（它没有返回正确的结果）。

MATCH (u:User)-[r:WROTE|REPOSTED]->(post:Post)
WITH (CASE WHEN r.created_date IS NOT NULL THEN r.created_date ELSE post.date END) as repost_date, post
SET post.repost_date = repost_date
RETURN post, repost_date
ORDER BY repost_date DESC
LIMIT 10

是否有另一种方法来获取并返回两个日期（当两者都存在时，即它是一个 REPOST）？

提前谢谢你！

Answer 1

有几种方法可以实现您想要的。可能最简单的是：

MATCH (u:User)-[r:WROTE|REPOSTED]->(post:Post)
WITH post, coalesce(r.created_date, post.created_date) AS date
ORDER BY date DESC
LIMIT 10
RETURN post

您也可以使用子查询 UNION，然后使用后过滤

MATCH (u:User)
CALL {
  MATCH (u)-[:WROTE]->(p:Post)
  RETURN p, p.created_date as date
  UNION 
  MATCH (u)-[r:REPOSTED]->(p:Post)
  RETURN p, r.created_date as date
}
WITH p, date
ORDER BY date DESC
LIMIT 10
RETURN p

第三种选择是使用 CASE 语句

MATCH (u:User)-[r:WROTE|REPOSTED]->(post:Post)
WITH post, CASE WHEN r:REPOSTED THEN r.created_date ELSE post.created_date END AS date
ORDER BY date DESC
LIMIT 10
RETURN post

您可以使用 PROFILE 子句来查看什么是最好的