在 apoc 触发器中创建 apoc 过程时出现 Neo4j 语法异常

Question

我正在一个 apoc 触发器中创建一个 apoc 过程。日志中的错误说明了这一点

" org.neo4j.exceptions.SyntaxException：变量 node 未定义（第 1 行，第 26 列（偏移量：25）） "MATCH(p1:SPerson { name: node.name}) CREATE (p1)-[:Enrolled]->(c)"

"

我的 apoc 触发代码

 CALL apoc.trigger.add('loadEnrollments',   
"UNWIND apoc.trigger.nodesByLabel($assignedLabels, 'Enrollment') AS node
 MERGE (p1:SPerson { name: node.name, cell: node.cell, created_at: node.created_at})
 WITH p1, node
 MATCH (c:Course {name: 'Paradigm Shifting 101'})
 MATCH (n:SPerson)
 WITH p1, node, COUNT(n) as size
 CALL apoc.do.when(
 size>3,'MERGE (p1)-[:Waitlist]->(c)',
 'MATCH(p1:SPerson { name: node.name}) CREATE (p1)-[:Enrolled]->(c)') YIELD value
 DETACH DELETE node", 
 { phase: 'after' });

Answer 1

关于您的直接问题，您需要将node 传递给apoc.do.when，以便其内部查询可以访问它。

但是，实际上，您应该更改查询，以便内部查询甚至不需要执行MATCH：

CALL apoc.trigger.add(
  'loadEnrollments',   
  "UNWIND apoc.trigger.nodesByLabel($assignedLabels, 'Enrollment') AS node
   MERGE (p1:SPerson { name: node.name, cell: node.cell, created_at: node.created_at})
   WITH p1, node
   MATCH (c:Course {name: 'Paradigm Shifting 101'})
   MATCH (n:SPerson)
   WITH p1, c, node, COUNT(n) as size
   CALL apoc.do.when(
     size>3,
     'MERGE (p1)-[:Waitlist]->(c)',
     'MERGE (p1)-[:Enrolled]->(c)',
     {p1: p1, c: c}
   ) YIELD value
   DETACH DELETE node", 
   { phase: 'after' }
);