如何在 SSMS 中使用 DAX 查询返回度量值？

Question

在我的表格模型中，我遇到了数据被复制的问题。这是该数据的来源：

HV Item Level Amount :=
IF (
    OR (
        MAX ( 'Item Hierarchy'[Depth] ) < [Level of Item Hierarchy],
        MAX ( 'Product Hierarchy'[Level Number] ) < [Level of Product Hierarchy]
    ),
    BLANK (),
    CALCULATE (
        [HV Dollar Amt],
        'R R2M Group',
        'P R2M Group',
        FILTER (
            'Item Hierarchy',
            'Item Hierarchy'[Depth] = MIN ( 'Item Hierarchy'[Depth] )
        )
    )
)

我想在分析服务上运行它，这样我就可以知道为什么数字不正确。

但是，我该怎么做呢？我是 DAX 新手，我可以看到，如果我运行 evaluate 'table_name'，它可以工作，但我需要运行上面的整个表达式。

有人可以帮我解决这个问题吗？

Answer 1

EVALUATE 总是返回一个表格，但您可以像这样返回一个单单元格表格：

DEFINE
MEASURE 'TableName'[HV Item Level Amount] =
    IF (
        OR (
            MAX ( 'Item Hierarchy'[Depth] ) < [Level of Item Hierarchy],
            MAX ( 'Product Hierarchy'[Level Number] ) < [Level of Product Hierarchy]
        ),
        BLANK (),
        CALCULATE (
            [HV Dollar Amt],
            'R R2M Group',
            'P R2M Group',
            FILTER (
                'Item Hierarchy',
                'Item Hierarchy'[Depth] = MIN ( 'Item Hierarchy'[Depth] )
            )
        )
    )
EVALUATE { 'TableName'[HV Item Level Amount] }

这应该返回表格

Value
-------
<Measure Output>

在逗号分隔值序列周围使用花括号 {...} 会创建一个列表，这在 DAX 中等效于具有通用列名称 Value 的单列表。